lib/Target/X86/X86InstrFormats.td

   1 //===-- X86InstrFormats.td - X86 Instruction Formats -------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // X86 Instruction Format Definitions.
  12 //
  13
  14 // Format specifies the encoding used by the instruction.  This is part of the
  15 // ad-hoc solution used to emit machine instruction encodings by our machine
  16 // code emitter.
  17 class Format<bits<7> val> {
  18   bits<7> Value = val;
  19 }
  20
  21 def Pseudo     : Format<0>; def RawFrm     : Format<1>;
  22 def AddRegFrm  : Format<2>; def MRMDestReg : Format<3>;
  23 def MRMDestMem : Format<4>; def MRMSrcReg  : Format<5>;
  24 def MRMSrcMem  : Format<6>; def RawFrmMemOffs : Format<7>;
  25 def RawFrmSrc  : Format<8>; def RawFrmDst     : Format<9>;
  26 def RawFrmDstSrc: Format<10>;
  27 def RawFrmImm8 : Format<11>;
  28 def RawFrmImm16 : Format<12>;
  29 def MRMXr  : Format<14>; def MRMXm  : Format<15>;
  30 def MRM0r  : Format<16>; def MRM1r  : Format<17>; def MRM2r  : Format<18>;
  31 def MRM3r  : Format<19>; def MRM4r  : Format<20>; def MRM5r  : Format<21>;
  32 def MRM6r  : Format<22>; def MRM7r  : Format<23>;
  33 def MRM0m  : Format<24>; def MRM1m  : Format<25>; def MRM2m  : Format<26>;
  34 def MRM3m  : Format<27>; def MRM4m  : Format<28>; def MRM5m  : Format<29>;
  35 def MRM6m  : Format<30>; def MRM7m  : Format<31>;
  36 def MRM_C0 : Format<32>; def MRM_C1 : Format<33>; def MRM_C2 : Format<34>;
  37 def MRM_C3 : Format<35>; def MRM_C4 : Format<36>; def MRM_C8 : Format<37>;
  38 def MRM_C9 : Format<38>; def MRM_CA : Format<39>; def MRM_CB : Format<40>;
  39 def MRM_CF : Format<41>; def MRM_D0 : Format<42>; def MRM_D1 : Format<43>;
  40 def MRM_D4 : Format<44>; def MRM_D5 : Format<45>; def MRM_D6 : Format<46>;
  41 def MRM_D7 : Format<47>; def MRM_D8 : Format<48>; def MRM_D9 : Format<49>;
  42 def MRM_DA : Format<50>; def MRM_DB : Format<51>; def MRM_DC : Format<52>;
  43 def MRM_DD : Format<53>; def MRM_DE : Format<54>; def MRM_DF : Format<55>;
  44 def MRM_E0 : Format<56>; def MRM_E1 : Format<57>; def MRM_E2 : Format<58>;
  45 def MRM_E3 : Format<59>; def MRM_E4 : Format<60>; def MRM_E5 : Format<61>;
  46 def MRM_E8 : Format<62>; def MRM_E9 : Format<63>; def MRM_EA : Format<64>;
  47 def MRM_EB : Format<65>; def MRM_EC : Format<66>; def MRM_ED : Format<67>;
  48 def MRM_EE : Format<68>; def MRM_F0 : Format<69>; def MRM_F1 : Format<70>;
  49 def MRM_F2 : Format<71>; def MRM_F3 : Format<72>; def MRM_F4 : Format<73>;
  50 def MRM_F5 : Format<74>; def MRM_F6 : Format<75>; def MRM_F7 : Format<76>;
  51 def MRM_F8 : Format<77>; def MRM_F9 : Format<78>; def MRM_FA : Format<79>;
  52 def MRM_FB : Format<80>; def MRM_FC : Format<81>; def MRM_FD : Format<82>;
  53 def MRM_FE : Format<83>; def MRM_FF : Format<84>;
  54
  55 // ImmType - This specifies the immediate type used by an instruction. This is
  56 // part of the ad-hoc solution used to emit machine instruction encodings by our
  57 // machine code emitter.
  58 class ImmType<bits<4> val> {
  59   bits<4> Value = val;
  60 }
  61 def NoImm      : ImmType<0>;
  62 def Imm8       : ImmType<1>;
  63 def Imm8PCRel  : ImmType<2>;
  64 def Imm16      : ImmType<3>;
  65 def Imm16PCRel : ImmType<4>;
  66 def Imm32      : ImmType<5>;
  67 def Imm32PCRel : ImmType<6>;
  68 def Imm32S     : ImmType<7>;
  69 def Imm64      : ImmType<8>;
  70
  71 // FPFormat - This specifies what form this FP instruction has.  This is used by
  72 // the Floating-Point stackifier pass.
  73 class FPFormat<bits<3> val> {
  74   bits<3> Value = val;
  75 }
  76 def NotFP      : FPFormat<0>;
  77 def ZeroArgFP  : FPFormat<1>;
  78 def OneArgFP   : FPFormat<2>;
  79 def OneArgFPRW : FPFormat<3>;
  80 def TwoArgFP   : FPFormat<4>;
  81 def CompareFP  : FPFormat<5>;
  82 def CondMovFP  : FPFormat<6>;
  83 def SpecialFP  : FPFormat<7>;
  84
  85 // Class specifying the SSE execution domain, used by the SSEDomainFix pass.
  86 // Keep in sync with tables in X86InstrInfo.cpp.
  87 class Domain<bits<2> val> {
  88   bits<2> Value = val;
  89 }
  90 def GenericDomain   : Domain<0>;
  91 def SSEPackedSingle : Domain<1>;
  92 def SSEPackedDouble : Domain<2>;
  93 def SSEPackedInt    : Domain<3>;
  94
  95 // Class specifying the vector form of the decompressed
  96 // displacement of 8-bit.
  97 class CD8VForm<bits<3> val> {
  98   bits<3> Value = val;
  99 }
 100 def CD8VF  : CD8VForm<0>;  // v := VL
 101 def CD8VH  : CD8VForm<1>;  // v := VL/2
 102 def CD8VQ  : CD8VForm<2>;  // v := VL/4
 103 def CD8VO  : CD8VForm<3>;  // v := VL/8
 104 // The tuple (subvector) forms.
 105 def CD8VT1 : CD8VForm<4>;  // v := 1
 106 def CD8VT2 : CD8VForm<5>;  // v := 2
 107 def CD8VT4 : CD8VForm<6>;  // v := 4
 108 def CD8VT8 : CD8VForm<7>;  // v := 8
 109
 110 // Class specifying the prefix used an opcode extension.
 111 class Prefix<bits<3> val> {
 112   bits<3> Value = val;
 113 }
 114 def NoPrfx : Prefix<0>;
 115 def PS     : Prefix<1>;
 116 def PD     : Prefix<2>;
 117 def XS     : Prefix<3>;
 118 def XD     : Prefix<4>;
 119
 120 // Class specifying the opcode map.
 121 class Map<bits<3> val> {
 122   bits<3> Value = val;
 123 }
 124 def OB   : Map<0>;
 125 def TB   : Map<1>;
 126 def T8   : Map<2>;
 127 def TA   : Map<3>;
 128 def XOP8 : Map<4>;
 129 def XOP9 : Map<5>;
 130 def XOPA : Map<6>;
 131
 132 // Class specifying the encoding
 133 class Encoding<bits<2> val> {
 134   bits<2> Value = val;
 135 }
 136 def EncNormal : Encoding<0>;
 137 def EncVEX    : Encoding<1>;
 138 def EncXOP    : Encoding<2>;
 139 def EncEVEX   : Encoding<3>;
 140
 141 // Operand size for encodings that change based on mode.
 142 class OperandSize<bits<2> val> {
 143   bits<2> Value = val;
 144 }
 145 def OpSizeFixed : OperandSize<0>; // Never needs a 0x66 prefix.
 146 def OpSize16    : OperandSize<1>; // Needs 0x66 prefix in 32-bit mode.
 147 def OpSize32    : OperandSize<2>; // Needs 0x66 prefix in 16-bit mode.
 148
 149 // Address size for encodings that change based on mode.
 150 class AddressSize<bits<2> val> {
 151   bits<2> Value = val;
 152 }
 153 def AdSizeX  : AddressSize<0>; // Address size determined using addr operand.
 154 def AdSize16 : AddressSize<1>; // Encodes a 16-bit address.
 155 def AdSize32 : AddressSize<2>; // Encodes a 32-bit address.
 156 def AdSize64 : AddressSize<3>; // Encodes a 64-bit address.
 157
 158 // Prefix byte classes which are used to indicate to the ad-hoc machine code
 159 // emitter that various prefix bytes are required.
 160 class OpSize16 { OperandSize OpSize = OpSize16; }
 161 class OpSize32 { OperandSize OpSize = OpSize32; }
 162 class AdSize16 { AddressSize AdSize = AdSize16; }
 163 class AdSize32 { AddressSize AdSize = AdSize32; }
 164 class AdSize64 { AddressSize AdSize = AdSize64; }
 165 class REX_W  { bit hasREX_WPrefix = 1; }
 166 class LOCK   { bit hasLockPrefix = 1; }
 167 class REP    { bit hasREPPrefix = 1; }
 168 class TB     { Map OpMap = TB; }
 169 class T8     { Map OpMap = T8; }
 170 class TA     { Map OpMap = TA; }
 171 class XOP8   { Map OpMap = XOP8; Prefix OpPrefix = PS; }
 172 class XOP9   { Map OpMap = XOP9; Prefix OpPrefix = PS; }
 173 class XOPA   { Map OpMap = XOPA; Prefix OpPrefix = PS; }
 174 class OBXS   { Prefix OpPrefix = XS; }
 175 class PS   : TB { Prefix OpPrefix = PS; }
 176 class PD   : TB { Prefix OpPrefix = PD; }
 177 class XD   : TB { Prefix OpPrefix = XD; }
 178 class XS   : TB { Prefix OpPrefix = XS; }
 179 class T8PS : T8 { Prefix OpPrefix = PS; }
 180 class T8PD : T8 { Prefix OpPrefix = PD; }
 181 class T8XD : T8 { Prefix OpPrefix = XD; }
 182 class T8XS : T8 { Prefix OpPrefix = XS; }
 183 class TAPS : TA { Prefix OpPrefix = PS; }
 184 class TAPD : TA { Prefix OpPrefix = PD; }
 185 class TAXD : TA { Prefix OpPrefix = XD; }
 186 class VEX    { Encoding OpEnc = EncVEX; }
 187 class VEX_W  { bit hasVEX_WPrefix = 1; }
 188 class VEX_4V : VEX { bit hasVEX_4V = 1; }
 189 class VEX_4VOp3 : VEX { bit hasVEX_4VOp3 = 1; }
 190 class VEX_I8IMM { bit hasVEX_i8ImmReg = 1; }
 191 class VEX_L  { bit hasVEX_L = 1; }
 192 class VEX_LIG { bit ignoresVEX_L = 1; }
 193 class EVEX : VEX { Encoding OpEnc = EncEVEX; }
 194 class EVEX_4V : VEX_4V { Encoding OpEnc = EncEVEX; }
 195 class EVEX_K { bit hasEVEX_K = 1; }
 196 class EVEX_KZ : EVEX_K { bit hasEVEX_Z = 1; }
 197 class EVEX_B { bit hasEVEX_B = 1; }
 198 class EVEX_RC { bit hasEVEX_RC = 1; }
 199 class EVEX_V512 { bit hasEVEX_L2 = 1; bit hasVEX_L = 0; }
 200 class EVEX_V256 { bit hasEVEX_L2 = 0; bit hasVEX_L = 1; }
 201 class EVEX_V128 { bit hasEVEX_L2 = 0; bit hasVEX_L = 0; }
 202
 203 // Specify AVX512 8-bit compressed displacement encoding based on the vector
 204 // element size in bits (8, 16, 32, 64) and the CDisp8 form.
 205 class EVEX_CD8<int esize, CD8VForm form> {
 206   int CD8_EltSize = !srl(esize, 3);
 207   bits<3> CD8_Form = form.Value;
 208 }
 209
 210 class Has3DNow0F0FOpcode  { bit has3DNow0F0FOpcode = 1; }
 211 class MemOp4 { bit hasMemOp4Prefix = 1; }
 212 class XOP { Encoding OpEnc = EncXOP; }
 213 class XOP_4V : XOP { bit hasVEX_4V = 1; }
 214 class XOP_4VOp3 : XOP { bit hasVEX_4VOp3 = 1; }
 215
 216 class X86Inst<bits<8> opcod, Format f, ImmType i, dag outs, dag ins,
 217               string AsmStr,
 218               InstrItinClass itin,
 219               Domain d = GenericDomain>
 220   : Instruction {
 221   let Namespace = "X86";
 222
 223   bits<8> Opcode = opcod;
 224   Format Form = f;
 225   bits<7> FormBits = Form.Value;
 226   ImmType ImmT = i;
 227
 228   dag OutOperandList = outs;
 229   dag InOperandList = ins;
 230   string AsmString = AsmStr;
 231
 232   // If this is a pseudo instruction, mark it isCodeGenOnly.
 233   let isCodeGenOnly = !eq(!cast<string>(f), "Pseudo");
 234
 235   let Itinerary = itin;
 236
 237   //
 238   // Attributes specific to X86 instructions...
 239   //
 240   bit ForceDisassemble = 0; // Force instruction to disassemble even though it's
 241                             // isCodeGenonly. Needed to hide an ambiguous
 242                             // AsmString from the parser, but still disassemble.
 243
 244   OperandSize OpSize = OpSizeFixed; // Does this instruction's encoding change
 245                                     // based on operand size of the mode?
 246   bits<2> OpSizeBits = OpSize.Value;
 247   AddressSize AdSize = AdSizeX; // Does this instruction's encoding change
 248                                 // based on address size of the mode?
 249   bits<2> AdSizeBits = AdSize.Value;
 250
 251   Prefix OpPrefix = NoPrfx; // Which prefix byte does this inst have?
 252   bits<3> OpPrefixBits = OpPrefix.Value;
 253   Map OpMap = OB;           // Which opcode map does this inst have?
 254   bits<3> OpMapBits = OpMap.Value;
 255   bit hasREX_WPrefix  = 0;  // Does this inst require the REX.W prefix?
 256   FPFormat FPForm = NotFP;  // What flavor of FP instruction is this?
 257   bit hasLockPrefix = 0;    // Does this inst have a 0xF0 prefix?
 258   Domain ExeDomain = d;
 259   bit hasREPPrefix = 0;     // Does this inst have a REP prefix?
 260   Encoding OpEnc = EncNormal; // Encoding used by this instruction
 261   bits<2> OpEncBits = OpEnc.Value;
 262   bit hasVEX_WPrefix = 0;   // Does this inst set the VEX_W field?
 263   bit hasVEX_4V = 0;        // Does this inst require the VEX.VVVV field?
 264   bit hasVEX_4VOp3 = 0;     // Does this inst require the VEX.VVVV field to
 265                             // encode the third operand?
 266   bit hasVEX_i8ImmReg = 0;  // Does this inst require the last source register
 267                             // to be encoded in a immediate field?
 268   bit hasVEX_L = 0;         // Does this inst use large (256-bit) registers?
 269   bit ignoresVEX_L = 0;     // Does this instruction ignore the L-bit
 270   bit hasEVEX_K = 0;        // Does this inst require masking?
 271   bit hasEVEX_Z = 0;        // Does this inst set the EVEX_Z field?
 272   bit hasEVEX_L2 = 0;       // Does this inst set the EVEX_L2 field?
 273   bit hasEVEX_B = 0;        // Does this inst set the EVEX_B field?
 274   bits<3> CD8_Form = 0;     // Compressed disp8 form - vector-width.
 275   // Declare it int rather than bits<4> so that all bits are defined when
 276   // assigning to bits<7>.
 277   int CD8_EltSize = 0;      // Compressed disp8 form - element-size in bytes.
 278   bit has3DNow0F0FOpcode =0;// Wacky 3dNow! encoding?
 279   bit hasMemOp4Prefix = 0;  // Same bit as VEX_W, but used for swapping operands
 280   bit hasEVEX_RC = 0;       // Explicitly specified rounding control in FP instruction.
 281
 282   bits<2> EVEX_LL;
 283   let EVEX_LL{0} = hasVEX_L;
 284   let EVEX_LL{1} = hasEVEX_L2;
 285   // Vector size in bytes.
 286   bits<7> VectSize = !shl(16, EVEX_LL);
 287
 288   // The scaling factor for AVX512's compressed displacement is either
 289   //   - the size of a  power-of-two number of elements or
 290   //   - the size of a single element for broadcasts or
 291   //   - the total vector size divided by a power-of-two number.
 292   // Possible values are: 0 (non-AVX512 inst), 1, 2, 4, 8, 16, 32 and 64.
 293   bits<7> CD8_Scale = !if (!eq (OpEnc.Value, EncEVEX.Value),
 294                            !if (CD8_Form{2},
 295                                 !shl(CD8_EltSize, CD8_Form{1-0}),
 296                                 !if (hasEVEX_B,
 297                                      CD8_EltSize,
 298                                      !srl(VectSize, CD8_Form{1-0}))), 0);
 299
 300   // TSFlags layout should be kept in sync with X86BaseInfo.h.
 301   let TSFlags{6-0}   = FormBits;
 302   let TSFlags{8-7}   = OpSizeBits;
 303   let TSFlags{10-9}  = AdSizeBits;
 304   let TSFlags{13-11} = OpPrefixBits;
 305   let TSFlags{16-14} = OpMapBits;
 306   let TSFlags{17}    = hasREX_WPrefix;
 307   let TSFlags{21-18} = ImmT.Value;
 308   let TSFlags{24-22} = FPForm.Value;
 309   let TSFlags{25}    = hasLockPrefix;
 310   let TSFlags{26}    = hasREPPrefix;
 311   let TSFlags{28-27} = ExeDomain.Value;
 312   let TSFlags{30-29} = OpEncBits;
 313   let TSFlags{38-31} = Opcode;
 314   let TSFlags{39}    = hasVEX_WPrefix;
 315   let TSFlags{40}    = hasVEX_4V;
 316   let TSFlags{41}    = hasVEX_4VOp3;
 317   let TSFlags{42}    = hasVEX_i8ImmReg;
 318   let TSFlags{43}    = hasVEX_L;
 319   let TSFlags{44}    = ignoresVEX_L;
 320   let TSFlags{45}    = hasEVEX_K;
 321   let TSFlags{46}    = hasEVEX_Z;
 322   let TSFlags{47}    = hasEVEX_L2;
 323   let TSFlags{48}    = hasEVEX_B;
 324   // If we run out of TSFlags bits, it's possible to encode this in 3 bits.
 325   let TSFlags{55-49} = CD8_Scale;
 326   let TSFlags{56}    = has3DNow0F0FOpcode;
 327   let TSFlags{57}    = hasMemOp4Prefix;
 328   let TSFlags{58}    = hasEVEX_RC;
 329 }
 330
 331 class PseudoI<dag oops, dag iops, list<dag> pattern>
 332   : X86Inst<0, Pseudo, NoImm, oops, iops, "", NoItinerary> {
 333   let Pattern = pattern;
 334 }
 335
 336 class I<bits<8> o, Format f, dag outs, dag ins, string asm,
 337         list<dag> pattern, InstrItinClass itin = NoItinerary,
 338         Domain d = GenericDomain>
 339   : X86Inst<o, f, NoImm, outs, ins, asm, itin, d> {
 340   let Pattern = pattern;
 341   let CodeSize = 3;
 342 }
 343 class Ii8 <bits<8> o, Format f, dag outs, dag ins, string asm,
 344            list<dag> pattern, InstrItinClass itin = NoItinerary,
 345            Domain d = GenericDomain>
 346   : X86Inst<o, f, Imm8, outs, ins, asm, itin, d> {
 347   let Pattern = pattern;
 348   let CodeSize = 3;
 349 }
 350 class Ii8PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 351                list<dag> pattern, InstrItinClass itin = NoItinerary>
 352   : X86Inst<o, f, Imm8PCRel, outs, ins, asm, itin> {
 353   let Pattern = pattern;
 354   let CodeSize = 3;
 355 }
 356 class Ii16<bits<8> o, Format f, dag outs, dag ins, string asm,
 357            list<dag> pattern, InstrItinClass itin = NoItinerary>
 358   : X86Inst<o, f, Imm16, outs, ins, asm, itin> {
 359   let Pattern = pattern;
 360   let CodeSize = 3;
 361 }
 362 class Ii32<bits<8> o, Format f, dag outs, dag ins, string asm,
 363            list<dag> pattern, InstrItinClass itin = NoItinerary>
 364   : X86Inst<o, f, Imm32, outs, ins, asm, itin> {
 365   let Pattern = pattern;
 366   let CodeSize = 3;
 367 }
 368 class Ii32S<bits<8> o, Format f, dag outs, dag ins, string asm,
 369             list<dag> pattern, InstrItinClass itin = NoItinerary>
 370   : X86Inst<o, f, Imm32S, outs, ins, asm, itin> {
 371   let Pattern = pattern;
 372   let CodeSize = 3;
 373 }
 374
 375 class Ii16PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 376            list<dag> pattern, InstrItinClass itin = NoItinerary>
 377            : X86Inst<o, f, Imm16PCRel, outs, ins, asm, itin> {
 378   let Pattern = pattern;
 379   let CodeSize = 3;
 380 }
 381
 382 class Ii32PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 383            list<dag> pattern, InstrItinClass itin = NoItinerary>
 384   : X86Inst<o, f, Imm32PCRel, outs, ins, asm, itin> {
 385   let Pattern = pattern;
 386   let CodeSize = 3;
 387 }
 388
 389 // FPStack Instruction Templates:
 390 // FPI - Floating Point Instruction template.
 391 class FPI<bits<8> o, Format F, dag outs, dag ins, string asm,
 392           InstrItinClass itin = NoItinerary>
 393   : I<o, F, outs, ins, asm, [], itin> {}
 394
 395 // FpI_ - Floating Point Pseudo Instruction template. Not Predicated.
 396 class FpI_<dag outs, dag ins, FPFormat fp, list<dag> pattern,
 397            InstrItinClass itin = NoItinerary>
 398   : X86Inst<0, Pseudo, NoImm, outs, ins, "", itin> {
 399   let FPForm = fp;
 400   let Pattern = pattern;
 401 }
 402
 403 // Templates for instructions that use a 16- or 32-bit segmented address as
 404 //  their only operand: lcall (FAR CALL) and ljmp (FAR JMP)
 405 //
 406 //   Iseg16 - 16-bit segment selector, 16-bit offset
 407 //   Iseg32 - 16-bit segment selector, 32-bit offset
 408
 409 class Iseg16 <bits<8> o, Format f, dag outs, dag ins, string asm,
 410               list<dag> pattern, InstrItinClass itin = NoItinerary>
 411       : X86Inst<o, f, Imm16, outs, ins, asm, itin> {
 412   let Pattern = pattern;
 413   let CodeSize = 3;
 414 }
 415
 416 class Iseg32 <bits<8> o, Format f, dag outs, dag ins, string asm,
 417               list<dag> pattern, InstrItinClass itin = NoItinerary>
 418       : X86Inst<o, f, Imm32, outs, ins, asm, itin> {
 419   let Pattern = pattern;
 420   let CodeSize = 3;
 421 }
 422
 423 // SI - SSE 1 & 2 scalar instructions
 424 class SI<bits<8> o, Format F, dag outs, dag ins, string asm,
 425          list<dag> pattern, InstrItinClass itin = NoItinerary>
 426       : I<o, F, outs, ins, asm, pattern, itin> {
 427   let Predicates = !if(!eq(OpEnc.Value, EncEVEX.Value), [HasAVX512],
 428                    !if(!eq(OpEnc.Value, EncVEX.Value), [UseAVX],
 429                    !if(!eq(OpPrefix.Value, XS.Value), [UseSSE1],
 430                    !if(!eq(OpPrefix.Value, XD.Value), [UseSSE2],
 431                    !if(!eq(OpPrefix.Value, PD.Value), [UseSSE2],
 432                    [UseSSE1])))));
 433
 434   // AVX instructions have a 'v' prefix in the mnemonic
 435   let AsmString = !if(!eq(OpEnc.Value, EncEVEX.Value), !strconcat("v", asm),
 436                   !if(!eq(OpEnc.Value, EncVEX.Value), !strconcat("v", asm),
 437                   asm));
 438 }
 439
 440 // SIi8 - SSE 1 & 2 scalar instructions
 441 class SIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 442            list<dag> pattern, InstrItinClass itin = NoItinerary>
 443       : Ii8<o, F, outs, ins, asm, pattern, itin> {
 444   let Predicates = !if(!eq(OpEnc.Value, EncEVEX.Value), [HasAVX512],
 445                    !if(!eq(OpEnc.Value, EncVEX.Value), [UseAVX],
 446                    !if(!eq(OpPrefix.Value, XS.Value), [UseSSE1],
 447                    [UseSSE2])));
 448
 449   // AVX instructions have a 'v' prefix in the mnemonic
 450   let AsmString = !if(!eq(OpEnc.Value, EncEVEX.Value), !strconcat("v", asm),
 451                   !if(!eq(OpEnc.Value, EncVEX.Value), !strconcat("v", asm),
 452                   asm));
 453 }
 454
 455 // PI - SSE 1 & 2 packed instructions
 456 class PI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern,
 457          InstrItinClass itin, Domain d>
 458       : I<o, F, outs, ins, asm, pattern, itin, d> {
 459   let Predicates = !if(!eq(OpEnc.Value, EncEVEX.Value), [HasAVX512],
 460                    !if(!eq(OpEnc.Value, EncVEX.Value), [HasAVX],
 461                    !if(!eq(OpPrefix.Value, PD.Value), [UseSSE2],
 462                    [UseSSE1])));
 463
 464   // AVX instructions have a 'v' prefix in the mnemonic
 465   let AsmString = !if(!eq(OpEnc.Value, EncEVEX.Value), !strconcat("v", asm),
 466                   !if(!eq(OpEnc.Value, EncVEX.Value), !strconcat("v", asm),
 467                   asm));
 468 }
 469
 470 // MMXPI - SSE 1 & 2 packed instructions with MMX operands
 471 class MMXPI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern,
 472             InstrItinClass itin, Domain d>
 473       : I<o, F, outs, ins, asm, pattern, itin, d> {
 474   let Predicates = !if(!eq(OpPrefix.Value, PD.Value), [HasSSE2],
 475                        [HasSSE1]);
 476 }
 477
 478 // PIi8 - SSE 1 & 2 packed instructions with immediate
 479 class PIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 480            list<dag> pattern, InstrItinClass itin, Domain d>
 481       : Ii8<o, F, outs, ins, asm, pattern, itin, d> {
 482   let Predicates = !if(!eq(OpEnc.Value, EncEVEX.Value), [HasAVX512],
 483                    !if(!eq(OpEnc.Value, EncVEX.Value), [HasAVX],
 484                    !if(!eq(OpPrefix.Value, PD.Value), [UseSSE2],
 485                    [UseSSE1])));
 486
 487   // AVX instructions have a 'v' prefix in the mnemonic
 488   let AsmString = !if(!eq(OpEnc.Value, EncEVEX.Value), !strconcat("v", asm),
 489                   !if(!eq(OpEnc.Value, EncVEX.Value), !strconcat("v", asm),
 490                   asm));
 491 }
 492
 493 // SSE1 Instruction Templates:
 494 //
 495 //   SSI   - SSE1 instructions with XS prefix.
 496 //   PSI   - SSE1 instructions with PS prefix.
 497 //   PSIi8 - SSE1 instructions with ImmT == Imm8 and PS prefix.
 498 //   VSSI  - SSE1 instructions with XS prefix in AVX form.
 499 //   VPSI  - SSE1 instructions with PS prefix in AVX form, packed single.
 500
 501 class SSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 502           list<dag> pattern, InstrItinClass itin = NoItinerary>
 503       : I<o, F, outs, ins, asm, pattern, itin>, XS, Requires<[UseSSE1]>;
 504 class SSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 505             list<dag> pattern, InstrItinClass itin = NoItinerary>
 506       : Ii8<o, F, outs, ins, asm, pattern, itin>, XS, Requires<[UseSSE1]>;
 507 class PSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 508           list<dag> pattern, InstrItinClass itin = NoItinerary>
 509       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedSingle>, PS,
 510         Requires<[UseSSE1]>;
 511 class PSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 512             list<dag> pattern, InstrItinClass itin = NoItinerary>
 513       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedSingle>, PS,
 514         Requires<[UseSSE1]>;
 515 class VSSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 516            list<dag> pattern, InstrItinClass itin = NoItinerary>
 517       : I<o, F, outs, ins, !strconcat("v", asm), pattern, itin>, XS,
 518         Requires<[HasAVX]>;
 519 class VPSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 520            list<dag> pattern, InstrItinClass itin = NoItinerary>
 521       : I<o, F, outs, ins, !strconcat("v", asm), pattern, itin, SSEPackedSingle>, PS,
 522         Requires<[HasAVX]>;
 523
 524 // SSE2 Instruction Templates:
 525 //
 526 //   SDI    - SSE2 instructions with XD prefix.
 527 //   SDIi8  - SSE2 instructions with ImmT == Imm8 and XD prefix.
 528 //   S2SI   - SSE2 instructions with XS prefix.
 529 //   SSDIi8 - SSE2 instructions with ImmT == Imm8 and XS prefix.
 530 //   PDI    - SSE2 instructions with PD prefix, packed double domain.
 531 //   PDIi8  - SSE2 instructions with ImmT == Imm8 and PD prefix.
 532 //   VSDI   - SSE2 scalar instructions with XD prefix in AVX form.
 533 //   VPDI   - SSE2 vector instructions with PD prefix in AVX form,
 534 //                 packed double domain.
 535 //   VS2I   - SSE2 scalar instructions with PD prefix in AVX form.
 536 //   S2I    - SSE2 scalar instructions with PD prefix.
 537 //   MMXSDIi8  - SSE2 instructions with ImmT == Imm8 and XD prefix as well as
 538 //               MMX operands.
 539 //   MMXSSDIi8 - SSE2 instructions with ImmT == Imm8 and XS prefix as well as
 540 //               MMX operands.
 541
 542 class SDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 543           list<dag> pattern, InstrItinClass itin = NoItinerary>
 544       : I<o, F, outs, ins, asm, pattern, itin>, XD, Requires<[UseSSE2]>;
 545 class SDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 546             list<dag> pattern, InstrItinClass itin = NoItinerary>
 547       : Ii8<o, F, outs, ins, asm, pattern, itin>, XD, Requires<[UseSSE2]>;
 548 class S2SI<bits<8> o, Format F, dag outs, dag ins, string asm,
 549            list<dag> pattern, InstrItinClass itin = NoItinerary>
 550       : I<o, F, outs, ins, asm, pattern, itin>, XS, Requires<[UseSSE2]>;
 551 class S2SIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 552              list<dag> pattern, InstrItinClass itin = NoItinerary>
 553       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[UseSSE2]>;
 554 class PDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 555           list<dag> pattern, InstrItinClass itin = NoItinerary>
 556       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedDouble>, PD,
 557         Requires<[UseSSE2]>;
 558 class PDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 559             list<dag> pattern, InstrItinClass itin = NoItinerary>
 560       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedDouble>, PD,
 561         Requires<[UseSSE2]>;
 562 class VSDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 563            list<dag> pattern, InstrItinClass itin = NoItinerary>
 564       : I<o, F, outs, ins, !strconcat("v", asm), pattern, itin>, XD,
 565         Requires<[UseAVX]>;
 566 class VS2SI<bits<8> o, Format F, dag outs, dag ins, string asm,
 567             list<dag> pattern, InstrItinClass itin = NoItinerary>
 568       : I<o, F, outs, ins, !strconcat("v", asm), pattern, itin>, XS,
 569         Requires<[HasAVX]>;
 570 class VPDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 571            list<dag> pattern, InstrItinClass itin = NoItinerary>
 572       : I<o, F, outs, ins, !strconcat("v", asm), pattern, itin, SSEPackedDouble>,
 573         PD, Requires<[HasAVX]>;
 574 class VS2I<bits<8> o, Format F, dag outs, dag ins, string asm,
 575            list<dag> pattern, InstrItinClass itin = NoItinerary>
 576       : I<o, F, outs, ins, !strconcat("v", asm), pattern, itin>, PD,
 577         Requires<[UseAVX]>;
 578 class S2I<bits<8> o, Format F, dag outs, dag ins, string asm,
 579            list<dag> pattern, InstrItinClass itin = NoItinerary>
 580       : I<o, F, outs, ins, asm, pattern, itin>, PD, Requires<[UseSSE2]>;
 581 class MMXSDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 582                list<dag> pattern, InstrItinClass itin = NoItinerary>
 583       : Ii8<o, F, outs, ins, asm, pattern, itin>, XD, Requires<[HasSSE2]>;
 584 class MMXS2SIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 585                 list<dag> pattern, InstrItinClass itin = NoItinerary>
 586       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE2]>;
 587
 588 // SSE3 Instruction Templates:
 589 //
 590 //   S3I   - SSE3 instructions with PD prefixes.
 591 //   S3SI  - SSE3 instructions with XS prefix.
 592 //   S3DI  - SSE3 instructions with XD prefix.
 593
 594 class S3SI<bits<8> o, Format F, dag outs, dag ins, string asm,
 595            list<dag> pattern, InstrItinClass itin = NoItinerary>
 596       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedSingle>, XS,
 597         Requires<[UseSSE3]>;
 598 class S3DI<bits<8> o, Format F, dag outs, dag ins, string asm,
 599            list<dag> pattern, InstrItinClass itin = NoItinerary>
 600       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedDouble>, XD,
 601         Requires<[UseSSE3]>;
 602 class S3I<bits<8> o, Format F, dag outs, dag ins, string asm,
 603           list<dag> pattern, InstrItinClass itin = NoItinerary>
 604       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedDouble>, PD,
 605         Requires<[UseSSE3]>;
 606
 607
 608 // SSSE3 Instruction Templates:
 609 //
 610 //   SS38I - SSSE3 instructions with T8 prefix.
 611 //   SS3AI - SSSE3 instructions with TA prefix.
 612 //   MMXSS38I - SSSE3 instructions with T8 prefix and MMX operands.
 613 //   MMXSS3AI - SSSE3 instructions with TA prefix and MMX operands.
 614 //
 615 // Note: SSSE3 instructions have 64-bit and 128-bit versions. The 64-bit version
 616 // uses the MMX registers. The 64-bit versions are grouped with the MMX
 617 // classes. They need to be enabled even if AVX is enabled.
 618
 619 class SS38I<bits<8> o, Format F, dag outs, dag ins, string asm,
 620             list<dag> pattern, InstrItinClass itin = NoItinerary>
 621       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8PD,
 622         Requires<[UseSSSE3]>;
 623 class SS3AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 624             list<dag> pattern, InstrItinClass itin = NoItinerary>
 625       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TAPD,
 626         Requires<[UseSSSE3]>;
 627 class MMXSS38I<bits<8> o, Format F, dag outs, dag ins, string asm,
 628                list<dag> pattern, InstrItinClass itin = NoItinerary>
 629       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8PS,
 630         Requires<[HasSSSE3]>;
 631 class MMXSS3AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 632                list<dag> pattern, InstrItinClass itin = NoItinerary>
 633       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TAPS,
 634         Requires<[HasSSSE3]>;
 635
 636 // SSE4.1 Instruction Templates:
 637 //
 638 //   SS48I - SSE 4.1 instructions with T8 prefix.
 639 //   SS41AIi8 - SSE 4.1 instructions with TA prefix and ImmT == Imm8.
 640 //
 641 class SS48I<bits<8> o, Format F, dag outs, dag ins, string asm,
 642             list<dag> pattern, InstrItinClass itin = NoItinerary>
 643       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8PD,
 644         Requires<[UseSSE41]>;
 645 class SS4AIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 646             list<dag> pattern, InstrItinClass itin = NoItinerary>
 647       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TAPD,
 648         Requires<[UseSSE41]>;
 649
 650 // SSE4.2 Instruction Templates:
 651 //
 652 //   SS428I - SSE 4.2 instructions with T8 prefix.
 653 class SS428I<bits<8> o, Format F, dag outs, dag ins, string asm,
 654              list<dag> pattern, InstrItinClass itin = NoItinerary>
 655       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8PD,
 656         Requires<[UseSSE42]>;
 657
 658 //   SS42FI - SSE 4.2 instructions with T8XD prefix.
 659 // NOTE: 'HasSSE42' is used as SS42FI is only used for CRC32 insns.
 660 class SS42FI<bits<8> o, Format F, dag outs, dag ins, string asm,
 661              list<dag> pattern, InstrItinClass itin = NoItinerary>
 662       : I<o, F, outs, ins, asm, pattern, itin>, T8XD, Requires<[HasSSE42]>;
 663
 664 //   SS42AI = SSE 4.2 instructions with TA prefix
 665 class SS42AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 666              list<dag> pattern, InstrItinClass itin = NoItinerary>
 667       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TAPD,
 668         Requires<[UseSSE42]>;
 669
 670 // AVX Instruction Templates:
 671 //   Instructions introduced in AVX (no SSE equivalent forms)
 672 //
 673 //   AVX8I - AVX instructions with T8PD prefix.
 674 //   AVXAIi8 - AVX instructions with TAPD prefix and ImmT = Imm8.
 675 class AVX8I<bits<8> o, Format F, dag outs, dag ins, string asm,
 676             list<dag> pattern, InstrItinClass itin = NoItinerary>
 677       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8PD,
 678         Requires<[HasAVX]>;
 679 class AVXAIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 680               list<dag> pattern, InstrItinClass itin = NoItinerary>
 681       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TAPD,
 682         Requires<[HasAVX]>;
 683
 684 // AVX2 Instruction Templates:
 685 //   Instructions introduced in AVX2 (no SSE equivalent forms)
 686 //
 687 //   AVX28I - AVX2 instructions with T8PD prefix.
 688 //   AVX2AIi8 - AVX2 instructions with TAPD prefix and ImmT = Imm8.
 689 class AVX28I<bits<8> o, Format F, dag outs, dag ins, string asm,
 690             list<dag> pattern, InstrItinClass itin = NoItinerary>
 691       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8PD,
 692         Requires<[HasAVX2]>;
 693 class AVX2AIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 694               list<dag> pattern, InstrItinClass itin = NoItinerary>
 695       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TAPD,
 696         Requires<[HasAVX2]>;
 697
 698
 699 // AVX-512 Instruction Templates:
 700 //   Instructions introduced in AVX-512 (no SSE equivalent forms)
 701 //
 702 //   AVX5128I - AVX-512 instructions with T8PD prefix.
 703 //   AVX512AIi8 - AVX-512 instructions with TAPD prefix and ImmT = Imm8.
 704 //   AVX512PDI  - AVX-512 instructions with PD, double packed.
 705 //   AVX512PSI  - AVX-512 instructions with PS, single packed.
 706 //   AVX512XS8I - AVX-512 instructions with T8 and XS prefixes.
 707 //   AVX512XSI  - AVX-512 instructions with XS prefix, generic domain.
 708 //   AVX512BI   - AVX-512 instructions with PD, int packed domain.
 709 //   AVX512SI   - AVX-512 scalar instructions with PD prefix.
 710
 711 class AVX5128I<bits<8> o, Format F, dag outs, dag ins, string asm,
 712             list<dag> pattern, InstrItinClass itin = NoItinerary>
 713       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8PD,
 714         Requires<[HasAVX512]>;
 715 class AVX5128IBase : T8PD {
 716   Domain ExeDomain = SSEPackedInt;
 717 }
 718 class AVX512XS8I<bits<8> o, Format F, dag outs, dag ins, string asm,
 719             list<dag> pattern, InstrItinClass itin = NoItinerary>
 720       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8XS,
 721         Requires<[HasAVX512]>;
 722 class AVX512XSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 723             list<dag> pattern, InstrItinClass itin = NoItinerary>
 724       : I<o, F, outs, ins, asm, pattern, itin>, XS,
 725         Requires<[HasAVX512]>;
 726 class AVX512XDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 727             list<dag> pattern, InstrItinClass itin = NoItinerary>
 728       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, XD,
 729         Requires<[HasAVX512]>;
 730 class AVX512BI<bits<8> o, Format F, dag outs, dag ins, string asm,
 731             list<dag> pattern, InstrItinClass itin = NoItinerary>
 732       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, PD,
 733         Requires<[HasAVX512]>;
 734 class AVX512BIBase : PD {
 735   Domain ExeDomain = SSEPackedInt;
 736 }
 737 class AVX512BIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 738               list<dag> pattern, InstrItinClass itin = NoItinerary>
 739       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, PD,
 740         Requires<[HasAVX512]>;
 741 class AVX512BIi8Base : PD {
 742   Domain ExeDomain = SSEPackedInt;
 743   ImmType ImmT = Imm8;
 744 }
 745 class AVX512AIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 746               list<dag> pattern, InstrItinClass itin = NoItinerary>
 747       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TAPD,
 748         Requires<[HasAVX512]>;
 749 class AVX512AIi8Base : TAPD {
 750   Domain ExeDomain = SSEPackedInt;
 751   ImmType ImmT = Imm8;
 752 }
 753 class AVX512Ii8<bits<8> o, Format F, dag outs, dag ins, string asm,
 754               list<dag> pattern, InstrItinClass itin = NoItinerary>
 755       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>,
 756         Requires<[HasAVX512]>;
 757 class AVX512PDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 758            list<dag> pattern, InstrItinClass itin = NoItinerary>
 759       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedDouble>, PD,
 760         Requires<[HasAVX512]>;
 761 class AVX512PSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 762            list<dag> pattern, InstrItinClass itin = NoItinerary>
 763       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedSingle>, PS,
 764         Requires<[HasAVX512]>;
 765 class AVX512PIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 766               list<dag> pattern, Domain d, InstrItinClass itin = NoItinerary>
 767       : Ii8<o, F, outs, ins, asm, pattern, itin, d>, Requires<[HasAVX512]>;
 768 class AVX512PI<bits<8> o, Format F, dag outs, dag ins, string asm,
 769               list<dag> pattern, Domain d, InstrItinClass itin = NoItinerary>
 770       : I<o, F, outs, ins, asm, pattern, itin, d>, Requires<[HasAVX512]>;
 771 class AVX512FMA3<bits<8> o, Format F, dag outs, dag ins, string asm,
 772            list<dag>pattern, InstrItinClass itin = NoItinerary>
 773       : I<o, F, outs, ins, asm, pattern, itin>, T8PD,
 774         EVEX_4V, Requires<[HasAVX512]>;
 775 class AVX512FMA3Base : T8PD, EVEX_4V;
 776
 777 class AVX512<bits<8> o, Format F, dag outs, dag ins, string asm,
 778            list<dag>pattern, InstrItinClass itin = NoItinerary>
 779       : I<o, F, outs, ins, asm, pattern, itin>, Requires<[HasAVX512]>;
 780
 781 // AES Instruction Templates:
 782 //
 783 // AES8I
 784 // These use the same encoding as the SSE4.2 T8 and TA encodings.
 785 class AES8I<bits<8> o, Format F, dag outs, dag ins, string asm,
 786             list<dag>pattern, InstrItinClass itin = IIC_AES>
 787       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8PD,
 788         Requires<[HasAES]>;
 789
 790 class AESAI<bits<8> o, Format F, dag outs, dag ins, string asm,
 791             list<dag> pattern, InstrItinClass itin = NoItinerary>
 792       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TAPD,
 793         Requires<[HasAES]>;
 794
 795 // PCLMUL Instruction Templates
 796 class PCLMULIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 797                list<dag>pattern, InstrItinClass itin = NoItinerary>
 798       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TAPD,
 799         Requires<[HasPCLMUL]>;
 800
 801 class AVXPCLMULIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 802                   list<dag>pattern, InstrItinClass itin = NoItinerary>
 803       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TAPD,
 804         VEX_4V, Requires<[HasAVX, HasPCLMUL]>;
 805
 806 // FMA3 Instruction Templates
 807 class FMA3<bits<8> o, Format F, dag outs, dag ins, string asm,
 808            list<dag>pattern, InstrItinClass itin = NoItinerary>
 809       : I<o, F, outs, ins, asm, pattern, itin>, T8PD,
 810         VEX_4V, FMASC, Requires<[HasFMA]>;
 811
 812 // FMA4 Instruction Templates
 813 class FMA4<bits<8> o, Format F, dag outs, dag ins, string asm,
 814            list<dag>pattern, InstrItinClass itin = NoItinerary>
 815       : Ii8<o, F, outs, ins, asm, pattern, itin>, TAPD,
 816         VEX_4V, VEX_I8IMM, FMASC, Requires<[HasFMA4]>;
 817
 818 // XOP 2, 3 and 4 Operand Instruction Template
 819 class IXOP<bits<8> o, Format F, dag outs, dag ins, string asm,
 820            list<dag> pattern, InstrItinClass itin = NoItinerary>
 821       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedDouble>,
 822          XOP9, Requires<[HasXOP]>;
 823
 824 // XOP 2, 3 and 4 Operand Instruction Templates with imm byte
 825 class IXOPi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 826            list<dag> pattern, InstrItinClass itin = NoItinerary>
 827       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedDouble>,
 828          XOP8, Requires<[HasXOP]>;
 829
 830 //  XOP 5 operand instruction (VEX encoding!)
 831 class IXOP5<bits<8> o, Format F, dag outs, dag ins, string asm,
 832            list<dag>pattern, InstrItinClass itin = NoItinerary>
 833       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TAPD,
 834         VEX_4V, VEX_I8IMM, Requires<[HasXOP]>;
 835
 836 // X86-64 Instruction templates...
 837 //
 838
 839 class RI<bits<8> o, Format F, dag outs, dag ins, string asm,
 840          list<dag> pattern, InstrItinClass itin = NoItinerary>
 841       : I<o, F, outs, ins, asm, pattern, itin>, REX_W;
 842 class RIi8 <bits<8> o, Format F, dag outs, dag ins, string asm,
 843             list<dag> pattern, InstrItinClass itin = NoItinerary>
 844       : Ii8<o, F, outs, ins, asm, pattern, itin>, REX_W;
 845 class RIi16 <bits<8> o, Format F, dag outs, dag ins, string asm,
 846             list<dag> pattern, InstrItinClass itin = NoItinerary>
 847       : Ii16<o, F, outs, ins, asm, pattern, itin>, REX_W;
 848 class RIi32 <bits<8> o, Format F, dag outs, dag ins, string asm,
 849              list<dag> pattern, InstrItinClass itin = NoItinerary>
 850       : Ii32<o, F, outs, ins, asm, pattern, itin>, REX_W;
 851 class RIi32S <bits<8> o, Format F, dag outs, dag ins, string asm,
 852               list<dag> pattern, InstrItinClass itin = NoItinerary>
 853       : Ii32S<o, F, outs, ins, asm, pattern, itin>, REX_W;
 854
 855 class RIi64<bits<8> o, Format f, dag outs, dag ins, string asm,
 856             list<dag> pattern, InstrItinClass itin = NoItinerary>
 857   : X86Inst<o, f, Imm64, outs, ins, asm, itin>, REX_W {
 858   let Pattern = pattern;
 859   let CodeSize = 3;
 860 }
 861
 862 class RIi64_NOREX<bits<8> o, Format f, dag outs, dag ins, string asm,
 863             list<dag> pattern, InstrItinClass itin = NoItinerary>
 864   : X86Inst<o, f, Imm64, outs, ins, asm, itin> {
 865   let Pattern = pattern;
 866   let CodeSize = 3;
 867 }
 868
 869 class RS2I<bits<8> o, Format F, dag outs, dag ins, string asm,
 870            list<dag> pattern, InstrItinClass itin = NoItinerary>
 871       : S2I<o, F, outs, ins, asm, pattern, itin>, REX_W;
 872 class VRS2I<bits<8> o, Format F, dag outs, dag ins, string asm,
 873            list<dag> pattern, InstrItinClass itin = NoItinerary>
 874       : VS2I<o, F, outs, ins, asm, pattern, itin>, VEX_W;
 875
 876 // MMX Instruction templates
 877 //
 878
 879 // MMXI   - MMX instructions with TB prefix.
 880 // MMXI32 - MMX instructions with TB prefix valid only in 32 bit mode.
 881 // MMXI64 - MMX instructions with TB prefix valid only in 64 bit mode.
 882 // MMX2I  - MMX / SSE2 instructions with PD prefix.
 883 // MMXIi8 - MMX instructions with ImmT == Imm8 and PS prefix.
 884 // MMXIi8 - MMX instructions with ImmT == Imm8 and PS prefix.
 885 // MMXID  - MMX instructions with XD prefix.
 886 // MMXIS  - MMX instructions with XS prefix.
 887 class MMXI<bits<8> o, Format F, dag outs, dag ins, string asm,
 888            list<dag> pattern, InstrItinClass itin = NoItinerary>
 889       : I<o, F, outs, ins, asm, pattern, itin>, PS, Requires<[HasMMX]>;
 890 class MMXI32<bits<8> o, Format F, dag outs, dag ins, string asm,
 891              list<dag> pattern, InstrItinClass itin = NoItinerary>
 892       : I<o, F, outs, ins, asm, pattern, itin>, PS, Requires<[HasMMX,Not64BitMode]>;
 893 class MMXI64<bits<8> o, Format F, dag outs, dag ins, string asm,
 894              list<dag> pattern, InstrItinClass itin = NoItinerary>
 895       : I<o, F, outs, ins, asm, pattern, itin>, PS, Requires<[HasMMX,In64BitMode]>;
 896 class MMXRI<bits<8> o, Format F, dag outs, dag ins, string asm,
 897             list<dag> pattern, InstrItinClass itin = NoItinerary>
 898       : I<o, F, outs, ins, asm, pattern, itin>, PS, REX_W, Requires<[HasMMX]>;
 899 class MMX2I<bits<8> o, Format F, dag outs, dag ins, string asm,
 900             list<dag> pattern, InstrItinClass itin = NoItinerary>
 901       : I<o, F, outs, ins, asm, pattern, itin>, PD, Requires<[HasMMX]>;
 902 class MMXIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 903              list<dag> pattern, InstrItinClass itin = NoItinerary>
 904       : Ii8<o, F, outs, ins, asm, pattern, itin>, PS, Requires<[HasMMX]>;
 905 class MMXID<bits<8> o, Format F, dag outs, dag ins, string asm,
 906             list<dag> pattern, InstrItinClass itin = NoItinerary>
 907       : Ii8<o, F, outs, ins, asm, pattern, itin>, XD, Requires<[HasMMX]>;
 908 class MMXIS<bits<8> o, Format F, dag outs, dag ins, string asm,
 909             list<dag> pattern, InstrItinClass itin = NoItinerary>
 910       : Ii8<o, F, outs, ins, asm, pattern, itin>, XS, Requires<[HasMMX]>;