lib/Target/XCore/XCoreInstrInfo.td

   1 //===-- XCoreInstrInfo.td - Target Description for XCore ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the XCore instructions in TableGen format.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 // Uses of CP, DP are not currently reflected in the patterns, since
  15 // having a physical register as an operand prevents loop hoisting and
  16 // since the value of these registers never changes during the life of the
  17 // function.
  18
  19 //===----------------------------------------------------------------------===//
  20 // Instruction format superclass.
  21 //===----------------------------------------------------------------------===//
  22
  23 include "XCoreInstrFormats.td"
  24
  25 //===----------------------------------------------------------------------===//
  26 // XCore specific DAG Nodes.
  27 //
  28
  29 // Call
  30 def SDT_XCoreBranchLink : SDTypeProfile<0, 1, [SDTCisPtrTy<0>]>;
  31 def XCoreBranchLink     : SDNode<"XCoreISD::BL",SDT_XCoreBranchLink,
  32                             [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
  33                              SDNPVariadic]>;
  34
  35 def XCoreRetsp       : SDNode<"XCoreISD::RETSP", SDTBrind,
  36                          [SDNPHasChain, SDNPOptInGlue, SDNPMayLoad]>;
  37
  38 def SDT_XCoreBR_JT    : SDTypeProfile<0, 2,
  39                                       [SDTCisVT<0, i32>, SDTCisVT<1, i32>]>;
  40
  41 def XCoreBR_JT : SDNode<"XCoreISD::BR_JT", SDT_XCoreBR_JT,
  42                         [SDNPHasChain]>;
  43
  44 def XCoreBR_JT32 : SDNode<"XCoreISD::BR_JT32", SDT_XCoreBR_JT,
  45                         [SDNPHasChain]>;
  46
  47 def SDT_XCoreAddress    : SDTypeProfile<1, 1,
  48                             [SDTCisSameAs<0, 1>, SDTCisPtrTy<0>]>;
  49
  50 def pcrelwrapper : SDNode<"XCoreISD::PCRelativeWrapper", SDT_XCoreAddress,
  51                            []>;
  52
  53 def dprelwrapper : SDNode<"XCoreISD::DPRelativeWrapper", SDT_XCoreAddress,
  54                            []>;
  55
  56 def cprelwrapper : SDNode<"XCoreISD::CPRelativeWrapper", SDT_XCoreAddress,
  57                            []>;
  58
  59 def SDT_XCoreStwsp    : SDTypeProfile<0, 2, [SDTCisInt<1>]>;
  60 def XCoreStwsp        : SDNode<"XCoreISD::STWSP", SDT_XCoreStwsp,
  61                                [SDNPHasChain, SDNPMayStore]>;
  62
  63 // These are target-independent nodes, but have target-specific formats.
  64 def SDT_XCoreCallSeqStart : SDCallSeqStart<[ SDTCisVT<0, i32> ]>;
  65 def SDT_XCoreCallSeqEnd   : SDCallSeqEnd<[ SDTCisVT<0, i32>,
  66                                         SDTCisVT<1, i32> ]>;
  67
  68 def callseq_start : SDNode<"ISD::CALLSEQ_START", SDT_XCoreCallSeqStart,
  69                            [SDNPHasChain, SDNPOutGlue]>;
  70 def callseq_end   : SDNode<"ISD::CALLSEQ_END",   SDT_XCoreCallSeqEnd,
  71                            [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
  72
  73 //===----------------------------------------------------------------------===//
  74 // Instruction Pattern Stuff
  75 //===----------------------------------------------------------------------===//
  76
  77 def div4_xform : SDNodeXForm<imm, [{
  78   // Transformation function: imm/4
  79   assert(N->getZExtValue() % 4 == 0);
  80   return getI32Imm(N->getZExtValue()/4);
  81 }]>;
  82
  83 def msksize_xform : SDNodeXForm<imm, [{
  84   // Transformation function: get the size of a mask
  85   assert(isMask_32(N->getZExtValue()));
  86   // look for the first non-zero bit
  87   return getI32Imm(32 - CountLeadingZeros_32(N->getZExtValue()));
  88 }]>;
  89
  90 def neg_xform : SDNodeXForm<imm, [{
  91   // Transformation function: -imm
  92   uint32_t value = N->getZExtValue();
  93   return getI32Imm(-value);
  94 }]>;
  95
  96 def bpwsub_xform : SDNodeXForm<imm, [{
  97   // Transformation function: 32-imm
  98   uint32_t value = N->getZExtValue();
  99   return getI32Imm(32-value);
 100 }]>;
 101
 102 def div4neg_xform : SDNodeXForm<imm, [{
 103   // Transformation function: -imm/4
 104   uint32_t value = N->getZExtValue();
 105   assert(-value % 4 == 0);
 106   return getI32Imm(-value/4);
 107 }]>;
 108
 109 def immUs4Neg : PatLeaf<(imm), [{
 110   uint32_t value = (uint32_t)N->getZExtValue();
 111   return (-value)%4 == 0 && (-value)/4 <= 11;
 112 }]>;
 113
 114 def immUs4 : PatLeaf<(imm), [{
 115   uint32_t value = (uint32_t)N->getZExtValue();
 116   return value%4 == 0 && value/4 <= 11;
 117 }]>;
 118
 119 def immUsNeg : PatLeaf<(imm), [{
 120   return -((uint32_t)N->getZExtValue()) <= 11;
 121 }]>;
 122
 123 def immUs : PatLeaf<(imm), [{
 124   return (uint32_t)N->getZExtValue() <= 11;
 125 }]>;
 126
 127 def immU6 : PatLeaf<(imm), [{
 128   return (uint32_t)N->getZExtValue() < (1 << 6);
 129 }]>;
 130
 131 def immU10 : PatLeaf<(imm), [{
 132   return (uint32_t)N->getZExtValue() < (1 << 10);
 133 }]>;
 134
 135 def immU16 : PatLeaf<(imm), [{
 136   return (uint32_t)N->getZExtValue() < (1 << 16);
 137 }]>;
 138
 139 def immU20 : PatLeaf<(imm), [{
 140   return (uint32_t)N->getZExtValue() < (1 << 20);
 141 }]>;
 142
 143 def immMskBitp : PatLeaf<(imm), [{ return immMskBitp(N); }]>;
 144
 145 def immBitp : PatLeaf<(imm), [{
 146   uint32_t value = (uint32_t)N->getZExtValue();
 147   return (value >= 1 && value <= 8)
 148           || value == 16
 149           || value == 24
 150           || value == 32;
 151 }]>;
 152
 153 def immBpwSubBitp : PatLeaf<(imm), [{
 154   uint32_t value = (uint32_t)N->getZExtValue();
 155   return (value >= 24 && value <= 31)
 156           || value == 16
 157           || value == 8
 158           || value == 0;
 159 }]>;
 160
 161 def lda16f : PatFrag<(ops node:$addr, node:$offset),
 162                      (add node:$addr, (shl node:$offset, 1))>;
 163 def lda16b : PatFrag<(ops node:$addr, node:$offset),
 164                      (sub node:$addr, (shl node:$offset, 1))>;
 165 def ldawf : PatFrag<(ops node:$addr, node:$offset),
 166                      (add node:$addr, (shl node:$offset, 2))>;
 167 def ldawb : PatFrag<(ops node:$addr, node:$offset),
 168                      (sub node:$addr, (shl node:$offset, 2))>;
 169
 170 // Instruction operand types
 171 def calltarget  : Operand<i32>;
 172 def brtarget : Operand<OtherVT>;
 173 def pclabel : Operand<i32>;
 174
 175 // Addressing modes
 176 def ADDRspii : ComplexPattern<i32, 2, "SelectADDRspii", [add, frameindex], []>;
 177 def ADDRdpii : ComplexPattern<i32, 2, "SelectADDRdpii", [add, dprelwrapper],
 178                  []>;
 179 def ADDRcpii : ComplexPattern<i32, 2, "SelectADDRcpii", [add, cprelwrapper],
 180                  []>;
 181
 182 // Address operands
 183 def MEMii : Operand<i32> {
 184   let PrintMethod = "printMemOperand";
 185   let DecoderMethod = "DecodeMEMiiOperand";
 186   let MIOperandInfo = (ops i32imm, i32imm);
 187 }
 188
 189 // Jump tables.
 190 def InlineJT : Operand<i32> {
 191   let PrintMethod = "printInlineJT";
 192 }
 193
 194 def InlineJT32 : Operand<i32> {
 195   let PrintMethod = "printInlineJT32";
 196 }
 197
 198 //===----------------------------------------------------------------------===//
 199 // Instruction Class Templates
 200 //===----------------------------------------------------------------------===//
 201
 202 // Three operand short
 203
 204 multiclass F3R_2RUS<bits<5> opc1, bits<5> opc2, string OpcStr, SDNode OpNode> {
 205   def _3r: _F3R<opc1, (outs GRRegs:$dst), (ins GRRegs:$b, GRRegs:$c),
 206                 !strconcat(OpcStr, " $dst, $b, $c"),
 207                 [(set GRRegs:$dst, (OpNode GRRegs:$b, GRRegs:$c))]>;
 208   def _2rus : _F2RUS<opc2, (outs GRRegs:$dst), (ins GRRegs:$b, i32imm:$c),
 209                      !strconcat(OpcStr, " $dst, $b, $c"),
 210                      [(set GRRegs:$dst, (OpNode GRRegs:$b, immUs:$c))]>;
 211 }
 212
 213 multiclass F3R_2RUS_np<bits<5> opc1, bits<5> opc2, string OpcStr> {
 214   def _3r: _F3R<opc1, (outs GRRegs:$dst), (ins GRRegs:$b, GRRegs:$c),
 215                 !strconcat(OpcStr, " $dst, $b, $c"), []>;
 216   def _2rus : _F2RUS<opc2, (outs GRRegs:$dst), (ins GRRegs:$b, i32imm:$c),
 217                      !strconcat(OpcStr, " $dst, $b, $c"), []>;
 218 }
 219
 220 multiclass F3R_2RBITP<bits<5> opc1, bits<5> opc2, string OpcStr,
 221                       SDNode OpNode> {
 222   def _3r: _F3R<opc1, (outs GRRegs:$dst), (ins GRRegs:$b, GRRegs:$c),
 223                 !strconcat(OpcStr, " $dst, $b, $c"),
 224                 [(set GRRegs:$dst, (OpNode GRRegs:$b, GRRegs:$c))]>;
 225   def _2rus : _F2RUSBitp<opc2, (outs GRRegs:$dst), (ins GRRegs:$b, i32imm:$c),
 226                          !strconcat(OpcStr, " $dst, $b, $c"),
 227                          [(set GRRegs:$dst, (OpNode GRRegs:$b, immBitp:$c))]>;
 228 }
 229
 230 class F3R<bits<5> opc, string OpcStr, SDNode OpNode> :
 231   _F3R<opc, (outs GRRegs:$dst), (ins GRRegs:$b, GRRegs:$c),
 232        !strconcat(OpcStr, " $dst, $b, $c"),
 233        [(set GRRegs:$dst, (OpNode GRRegs:$b, GRRegs:$c))]>;
 234
 235 class F3R_np<bits<5> opc, string OpcStr> :
 236   _F3R<opc, (outs GRRegs:$dst), (ins GRRegs:$b, GRRegs:$c),
 237        !strconcat(OpcStr, " $dst, $b, $c"), []>;
 238 // Three operand long
 239
 240 /// FL3R_L2RUS multiclass - Define a normal FL3R/FL2RUS pattern in one shot.
 241 multiclass FL3R_L2RUS<bits<9> opc1, bits<9> opc2, string OpcStr,
 242                       SDNode OpNode> {
 243   def _l3r: _FL3R<opc1, (outs GRRegs:$dst), (ins GRRegs:$b, GRRegs:$c),
 244                   !strconcat(OpcStr, " $dst, $b, $c"),
 245                   [(set GRRegs:$dst, (OpNode GRRegs:$b, GRRegs:$c))]>;
 246   def _l2rus : _FL2RUS<opc2, (outs GRRegs:$dst), (ins GRRegs:$b, i32imm:$c),
 247                        !strconcat(OpcStr, " $dst, $b, $c"),
 248                        [(set GRRegs:$dst, (OpNode GRRegs:$b, immUs:$c))]>;
 249 }
 250
 251 /// FL3R_L2RUS multiclass - Define a normal FL3R/FL2RUS pattern in one shot.
 252 multiclass FL3R_L2RBITP<bits<9> opc1, bits<9> opc2, string OpcStr,
 253                         SDNode OpNode> {
 254   def _l3r: _FL3R<opc1, (outs GRRegs:$dst), (ins GRRegs:$b, GRRegs:$c),
 255                   !strconcat(OpcStr, " $dst, $b, $c"),
 256                   [(set GRRegs:$dst, (OpNode GRRegs:$b, GRRegs:$c))]>;
 257   def _l2rus : _FL2RUSBitp<opc2, (outs GRRegs:$dst), (ins GRRegs:$b, i32imm:$c),
 258                            !strconcat(OpcStr, " $dst, $b, $c"),
 259                            [(set GRRegs:$dst, (OpNode GRRegs:$b, immBitp:$c))]>;
 260 }
 261
 262 class FL3R<bits<9> opc, string OpcStr, SDNode OpNode> :
 263   _FL3R<opc, (outs GRRegs:$dst), (ins GRRegs:$b, GRRegs:$c),
 264         !strconcat(OpcStr, " $dst, $b, $c"),
 265         [(set GRRegs:$dst, (OpNode GRRegs:$b, GRRegs:$c))]>;
 266
 267 // Register - U6
 268 // Operand register - U6
 269 multiclass FRU6_LRU6_branch<bits<6> opc, string OpcStr> {
 270   def _ru6: _FRU6<opc, (outs), (ins GRRegs:$a, brtarget:$b),
 271                   !strconcat(OpcStr, " $a, $b"), []>;
 272   def _lru6: _FLRU6<opc, (outs), (ins GRRegs:$a, brtarget:$b),
 273                     !strconcat(OpcStr, " $a, $b"), []>;
 274 }
 275
 276 multiclass FRU6_LRU6_backwards_branch<bits<6> opc, string OpcStr> {
 277   def _ru6: _FRU6<opc, (outs), (ins GRRegs:$a, brtarget:$b),
 278                   !strconcat(OpcStr, " $a, -$b"), []>;
 279   def _lru6: _FLRU6<opc, (outs), (ins GRRegs:$a, brtarget:$b),
 280                     !strconcat(OpcStr, " $a, -$b"), []>;
 281 }
 282
 283 multiclass FRU6_LRU6_cp<bits<6> opc, string OpcStr> {
 284   def _ru6: _FRU6<opc, (outs GRRegs:$a), (ins i32imm:$b),
 285                   !strconcat(OpcStr, " $a, cp[$b]"), []>;
 286   def _lru6: _FLRU6<opc, (outs GRRegs:$a), (ins i32imm:$b),
 287                     !strconcat(OpcStr, " $a, cp[$b]"), []>;
 288 }
 289
 290 // U6
 291 multiclass FU6_LU6<bits<10> opc, string OpcStr, SDNode OpNode> {
 292   def _u6: _FU6<opc, (outs), (ins i32imm:$a), !strconcat(OpcStr, " $a"),
 293                 [(OpNode immU6:$a)]>;
 294   def _lu6: _FLU6<opc, (outs), (ins i32imm:$a), !strconcat(OpcStr, " $a"),
 295                   [(OpNode immU16:$a)]>;
 296 }
 297
 298 multiclass FU6_LU6_int<bits<10> opc, string OpcStr, Intrinsic Int> {
 299   def _u6: _FU6<opc, (outs), (ins i32imm:$a), !strconcat(OpcStr, " $a"),
 300                 [(Int immU6:$a)]>;
 301   def _lu6: _FLU6<opc, (outs), (ins i32imm:$a), !strconcat(OpcStr, " $a"),
 302                   [(Int immU16:$a)]>;
 303 }
 304
 305 multiclass FU6_LU6_np<bits<10> opc, string OpcStr> {
 306   def _u6: _FU6<opc, (outs), (ins i32imm:$a), !strconcat(OpcStr, " $a"), []>;
 307   def _lu6: _FLU6<opc, (outs), (ins i32imm:$a), !strconcat(OpcStr, " $a"), []>;
 308 }
 309
 310 // Two operand short
 311
 312 class F2R_np<bits<6> opc, string OpcStr> :
 313   _F2R<opc, (outs GRRegs:$dst), (ins GRRegs:$b),
 314        !strconcat(OpcStr, " $dst, $b"), []>;
 315
 316 // Two operand long
 317
 318 //===----------------------------------------------------------------------===//
 319 // Pseudo Instructions
 320 //===----------------------------------------------------------------------===//
 321
 322 let Defs = [SP], Uses = [SP] in {
 323 def ADJCALLSTACKDOWN : PseudoInstXCore<(outs), (ins i32imm:$amt),
 324                                "# ADJCALLSTACKDOWN $amt",
 325                                [(callseq_start timm:$amt)]>;
 326 def ADJCALLSTACKUP : PseudoInstXCore<(outs), (ins i32imm:$amt1, i32imm:$amt2),
 327                             "# ADJCALLSTACKUP $amt1",
 328                             [(callseq_end timm:$amt1, timm:$amt2)]>;
 329 }
 330
 331 def LDWFI : PseudoInstXCore<(outs GRRegs:$dst), (ins MEMii:$addr),
 332                              "# LDWFI $dst, $addr",
 333                              [(set GRRegs:$dst, (load ADDRspii:$addr))]>;
 334
 335 def LDAWFI : PseudoInstXCore<(outs GRRegs:$dst), (ins MEMii:$addr),
 336                              "# LDAWFI $dst, $addr",
 337                              [(set GRRegs:$dst, ADDRspii:$addr)]>;
 338
 339 def STWFI : PseudoInstXCore<(outs), (ins GRRegs:$src, MEMii:$addr),
 340                             "# STWFI $src, $addr",
 341                             [(store GRRegs:$src, ADDRspii:$addr)]>;
 342
 343 // SELECT_CC_* - Used to implement the SELECT_CC DAG operation.  Expanded after
 344 // instruction selection into a branch sequence.
 345 let usesCustomInserter = 1 in {
 346   def SELECT_CC : PseudoInstXCore<(outs GRRegs:$dst),
 347                               (ins GRRegs:$cond, GRRegs:$T, GRRegs:$F),
 348                               "# SELECT_CC PSEUDO!",
 349                               [(set GRRegs:$dst,
 350                                  (select GRRegs:$cond, GRRegs:$T, GRRegs:$F))]>;
 351 }
 352
 353 //===----------------------------------------------------------------------===//
 354 // Instructions
 355 //===----------------------------------------------------------------------===//
 356
 357 // Three operand short
 358 defm ADD : F3R_2RUS<0b00010, 0b10010, "add", add>;
 359 defm SUB : F3R_2RUS<0b00011, 0b10011, "sub", sub>;
 360 let neverHasSideEffects = 1 in {
 361 defm EQ : F3R_2RUS_np<0b00110, 0b10110, "eq">;
 362 def LSS_3r : F3R_np<0b11000, "lss">;
 363 def LSU_3r : F3R_np<0b11001, "lsu">;
 364 }
 365 def AND_3r : F3R<0b00111, "and", and>;
 366 def OR_3r : F3R<0b01000, "or", or>;
 367
 368 let mayLoad=1 in {
 369 def LDW_3r : _F3R<0b01001, (outs GRRegs:$dst),
 370                   (ins GRRegs:$addr, GRRegs:$offset),
 371                   "ldw $dst, $addr[$offset]", []>;
 372
 373 def LDW_2rus : _F2RUS<0b00001, (outs GRRegs:$dst),
 374                       (ins GRRegs:$addr, i32imm:$offset),
 375                       "ldw $dst, $addr[$offset]", []>;
 376
 377 def LD16S_3r :  _F3R<0b10000, (outs GRRegs:$dst),
 378                      (ins GRRegs:$addr, GRRegs:$offset),
 379                      "ld16s $dst, $addr[$offset]", []>;
 380
 381 def LD8U_3r :  _F3R<0b10001, (outs GRRegs:$dst),
 382                     (ins GRRegs:$addr, GRRegs:$offset),
 383                     "ld8u $dst, $addr[$offset]", []>;
 384 }
 385
 386 let mayStore=1 in {
 387 def STW_l3r : _FL3R<0b000001100, (outs),
 388                     (ins GRRegs:$val, GRRegs:$addr, GRRegs:$offset),
 389                     "stw $val, $addr[$offset]", []>;
 390
 391 def STW_2rus : _F2RUS<0b0000, (outs),
 392                       (ins GRRegs:$val, GRRegs:$addr, i32imm:$offset),
 393                       "stw $val, $addr[$offset]", []>;
 394 }
 395
 396 defm SHL : F3R_2RBITP<0b00100, 0b10100, "shl", shl>;
 397 defm SHR : F3R_2RBITP<0b00101, 0b10101, "shr", srl>;
 398 // TODO tsetr
 399
 400 // Three operand long
 401 def LDAWF_l3r : _FL3R<0b000111100, (outs GRRegs:$dst),
 402                       (ins GRRegs:$addr, GRRegs:$offset),
 403                       "ldaw $dst, $addr[$offset]",
 404                       [(set GRRegs:$dst,
 405                          (ldawf GRRegs:$addr, GRRegs:$offset))]>;
 406
 407 let neverHasSideEffects = 1 in
 408 def LDAWF_l2rus : _FL2RUS<0b100111100, (outs GRRegs:$dst),
 409                           (ins GRRegs:$addr, i32imm:$offset),
 410                           "ldaw $dst, $addr[$offset]", []>;
 411
 412 def LDAWB_l3r : _FL3R<0b001001100, (outs GRRegs:$dst),
 413                       (ins GRRegs:$addr, GRRegs:$offset),
 414                       "ldaw $dst, $addr[-$offset]",
 415                       [(set GRRegs:$dst,
 416                          (ldawb GRRegs:$addr, GRRegs:$offset))]>;
 417
 418 let neverHasSideEffects = 1 in
 419 def LDAWB_l2rus : _FL2RUS<0b101001100, (outs GRRegs:$dst),
 420                          (ins GRRegs:$addr, i32imm:$offset),
 421                          "ldaw $dst, $addr[-$offset]", []>;
 422
 423 def LDA16F_l3r : _FL3R<0b001011100, (outs GRRegs:$dst),
 424                        (ins GRRegs:$addr, GRRegs:$offset),
 425                        "lda16 $dst, $addr[$offset]",
 426                        [(set GRRegs:$dst,
 427                           (lda16f GRRegs:$addr, GRRegs:$offset))]>;
 428
 429 def LDA16B_l3r : _FL3R<0b001101100, (outs GRRegs:$dst),
 430                        (ins GRRegs:$addr, GRRegs:$offset),
 431                        "lda16 $dst, $addr[-$offset]",
 432                        [(set GRRegs:$dst,
 433                           (lda16b GRRegs:$addr, GRRegs:$offset))]>;
 434
 435 def MUL_l3r : FL3R<0b001111100, "mul", mul>;
 436 // Instructions which may trap are marked as side effecting.
 437 let hasSideEffects = 1 in {
 438 def DIVS_l3r : FL3R<0b010001100, "divs", sdiv>;
 439 def DIVU_l3r : FL3R<0b010011100, "divu", udiv>;
 440 def REMS_l3r : FL3R<0b110001100, "rems", srem>;
 441 def REMU_l3r : FL3R<0b110011100, "remu", urem>;
 442 }
 443 def XOR_l3r : FL3R<0b000011100, "xor", xor>;
 444 defm ASHR : FL3R_L2RBITP<0b000101100, 0b100101100, "ashr", sra>;
 445
 446 let Constraints = "$src1 = $dst" in
 447 def CRC_l3r : _FL3RSrcDst<0b101011100, (outs GRRegs:$dst),
 448                           (ins GRRegs:$src1, GRRegs:$src2, GRRegs:$src3),
 449                           "crc32 $dst, $src2, $src3",
 450                           [(set GRRegs:$dst,
 451                              (int_xcore_crc32 GRRegs:$src1, GRRegs:$src2,
 452                                               GRRegs:$src3))]>;
 453
 454 // TODO inpw, outpw
 455 let mayStore=1 in {
 456 def ST16_l3r : _FL3R<0b100001100, (outs),
 457                      (ins GRRegs:$val, GRRegs:$addr, GRRegs:$offset),
 458                      "st16 $val, $addr[$offset]", []>;
 459
 460 def ST8_l3r : _FL3R<0b100011100, (outs),
 461                     (ins GRRegs:$val, GRRegs:$addr, GRRegs:$offset),
 462                     "st8 $val, $addr[$offset]", []>;
 463 }
 464
 465 // Four operand long
 466 let Constraints = "$e = $a,$f = $b" in {
 467 def MACCU_l4r : _FL4RSrcDstSrcDst<
 468   0b000001, (outs GRRegs:$a, GRRegs:$b),
 469   (ins GRRegs:$e, GRRegs:$f, GRRegs:$c, GRRegs:$d), "maccu $a, $b, $c, $d", []>;
 470
 471 def MACCS_l4r : _FL4RSrcDstSrcDst<
 472   0b000010, (outs GRRegs:$a, GRRegs:$b),
 473   (ins GRRegs:$e, GRRegs:$f, GRRegs:$c, GRRegs:$d), "maccs $a, $b, $c, $d", []>;
 474 }
 475
 476 let Constraints = "$e = $b" in
 477 def CRC8_l4r : _FL4RSrcDst<0b000000, (outs GRRegs:$a, GRRegs:$b),
 478                            (ins GRRegs:$e, GRRegs:$c, GRRegs:$d),
 479                            "crc8 $b, $a, $c, $d", []>;
 480
 481 // Five operand long
 482
 483 def LADD_l5r : _FL5R<0b000001, (outs GRRegs:$dst1, GRRegs:$dst2),
 484                      (ins GRRegs:$src1, GRRegs:$src2, GRRegs:$src3),
 485                      "ladd $dst2, $dst1, $src1, $src2, $src3",
 486                      []>;
 487
 488 def LSUB_l5r : _FL5R<0b000010, (outs GRRegs:$dst1, GRRegs:$dst2),
 489                      (ins GRRegs:$src1, GRRegs:$src2, GRRegs:$src3),
 490                      "lsub $dst2, $dst1, $src1, $src2, $src3", []>;
 491
 492 def LDIVU_l5r : _FL5R<0b000000, (outs GRRegs:$dst1, GRRegs:$dst2),
 493                       (ins GRRegs:$src1, GRRegs:$src2, GRRegs:$src3),
 494                       "ldivu $dst1, $dst2, $src3, $src1, $src2", []>;
 495
 496 // Six operand long
 497
 498 def LMUL_l6r : _FL6R<
 499   0b00000, (outs GRRegs:$dst1, GRRegs:$dst2),
 500   (ins GRRegs:$src1, GRRegs:$src2, GRRegs:$src3, GRRegs:$src4),
 501   "lmul $dst1, $dst2, $src1, $src2, $src3, $src4", []>;
 502
 503 // Register - U6
 504
 505 //let Uses = [DP] in ...
 506 let neverHasSideEffects = 1, isReMaterializable = 1 in
 507 def LDAWDP_ru6: _FRU6<0b011000, (outs GRRegs:$a), (ins MEMii:$b),
 508                       "ldaw $a, dp[$b]", []>;
 509
 510 let isReMaterializable = 1 in
 511 def LDAWDP_lru6: _FLRU6<0b011000, (outs GRRegs:$a), (ins MEMii:$b),
 512                         "ldaw $a, dp[$b]",
 513                         [(set GRRegs:$a, ADDRdpii:$b)]>;
 514
 515 let mayLoad=1 in
 516 def LDWDP_ru6: _FRU6<0b010110, (outs GRRegs:$a), (ins MEMii:$b),
 517                      "ldw $a, dp[$b]", []>;
 518
 519 def LDWDP_lru6: _FLRU6<0b010110, (outs GRRegs:$a), (ins MEMii:$b),
 520                        "ldw $a, dp[$b]",
 521                        [(set GRRegs:$a, (load ADDRdpii:$b))]>;
 522
 523 let mayStore=1 in
 524 def STWDP_ru6 : _FRU6<0b010100, (outs), (ins GRRegs:$a, MEMii:$b),
 525                       "stw $a, dp[$b]", []>;
 526
 527 def STWDP_lru6 : _FLRU6<0b010100, (outs), (ins GRRegs:$a, MEMii:$b),
 528                         "stw $a, dp[$b]",
 529                         [(store GRRegs:$a, ADDRdpii:$b)]>;
 530
 531 //let Uses = [CP] in ..
 532 let mayLoad = 1, isReMaterializable = 1, neverHasSideEffects = 1 in
 533 defm LDWCP : FRU6_LRU6_cp<0b011011, "ldw">;
 534
 535 let Uses = [SP] in {
 536 let mayStore=1 in {
 537 def STWSP_ru6 : _FRU6<0b010101, (outs), (ins GRRegs:$a, i32imm:$b),
 538                       "stw $a, sp[$b]",
 539                       [(XCoreStwsp GRRegs:$a, immU6:$b)]>;
 540
 541 def STWSP_lru6 : _FLRU6<0b010101, (outs), (ins GRRegs:$a, i32imm:$b),
 542                         "stw $a, sp[$b]",
 543                         [(XCoreStwsp GRRegs:$a, immU16:$b)]>;
 544 }
 545
 546 let mayLoad=1 in {
 547 def LDWSP_ru6 : _FRU6<0b010111, (outs GRRegs:$a), (ins i32imm:$b),
 548                       "ldw $a, sp[$b]", []>;
 549
 550 def LDWSP_lru6 : _FLRU6<0b010111, (outs GRRegs:$a), (ins i32imm:$b),
 551                         "ldw $a, sp[$b]", []>;
 552 }
 553
 554 let neverHasSideEffects = 1 in {
 555 def LDAWSP_ru6 : _FRU6<0b011001, (outs GRRegs:$a), (ins i32imm:$b),
 556                        "ldaw $a, sp[$b]", []>;
 557
 558 def LDAWSP_lru6 : _FLRU6<0b011001, (outs GRRegs:$a), (ins i32imm:$b),
 559                          "ldaw $a, sp[$b]", []>;
 560
 561 let isCodeGenOnly = 1 in
 562 def LDAWSP_ru6_RRegs : _FRU6<0b011001, (outs RRegs:$a), (ins i32imm:$b),
 563                              "ldaw $a, sp[$b]", []>;
 564
 565 let isCodeGenOnly = 1 in
 566 def LDAWSP_lru6_RRegs : _FLRU6<0b011001, (outs RRegs:$a), (ins i32imm:$b),
 567                                "ldaw $a, sp[$b]", []>;
 568 }
 569 }
 570
 571 let isReMaterializable = 1 in {
 572 def LDC_ru6 : _FRU6<0b011010, (outs GRRegs:$a), (ins i32imm:$b),
 573                     "ldc $a, $b", [(set GRRegs:$a, immU6:$b)]>;
 574
 575 def LDC_lru6 : _FLRU6<0b011010, (outs GRRegs:$a), (ins i32imm:$b),
 576                       "ldc $a, $b", [(set GRRegs:$a, immU16:$b)]>;
 577 }
 578
 579 def SETC_ru6 : _FRU6<0b111010, (outs), (ins GRRegs:$a, i32imm:$b),
 580                      "setc res[$a], $b",
 581                      [(int_xcore_setc GRRegs:$a, immU6:$b)]>;
 582
 583 def SETC_lru6 : _FLRU6<0b111010, (outs), (ins GRRegs:$a, i32imm:$b),
 584                        "setc res[$a], $b",
 585                        [(int_xcore_setc GRRegs:$a, immU16:$b)]>;
 586
 587 // Operand register - U6
 588 let isBranch = 1, isTerminator = 1 in {
 589 defm BRFT: FRU6_LRU6_branch<0b011100, "bt">;
 590 defm BRBT: FRU6_LRU6_backwards_branch<0b011101, "bt">;
 591 defm BRFF: FRU6_LRU6_branch<0b011110, "bf">;
 592 defm BRBF: FRU6_LRU6_backwards_branch<0b011111, "bf">;
 593 }
 594
 595 // U6
 596 let Defs = [SP], Uses = [SP] in {
 597 let neverHasSideEffects = 1 in
 598 defm EXTSP : FU6_LU6_np<0b0111011110, "extsp">;
 599 let mayStore = 1 in
 600 defm ENTSP : FU6_LU6_np<0b0111011101, "entsp">;
 601
 602 let isReturn = 1, isTerminator = 1, mayLoad = 1, isBarrier = 1 in {
 603 defm RETSP : FU6_LU6<0b0111011111, "retsp", XCoreRetsp>;
 604 }
 605 }
 606
 607 // TODO extdp, kentsp, krestsp, blat
 608 // getsr, kalli
 609 let isBranch = 1, isTerminator = 1, isBarrier = 1 in {
 610 def BRBU_u6 : _FU6<0b0111011100, (outs), (ins brtarget:$a), "bu -$a", []>;
 611
 612 def BRBU_lu6 : _FLU6<0b0111011100, (outs), (ins brtarget:$a), "bu -$a", []>;
 613
 614 def BRFU_u6 : _FU6<0b0111001100, (outs), (ins brtarget:$a), "bu $a", []>;
 615
 616 def BRFU_lu6 : _FLU6<0b0111001100, (outs), (ins brtarget:$a), "bu $a", []>;
 617 }
 618
 619 //let Uses = [CP] in ...
 620 let Defs = [R11], neverHasSideEffects = 1, isReMaterializable = 1 in
 621 def LDAWCP_u6: _FU6<0b0111111101, (outs), (ins MEMii:$a), "ldaw r11, cp[$a]",
 622                     []>;
 623
 624 let Defs = [R11], isReMaterializable = 1 in
 625 def LDAWCP_lu6: _FLU6<0b0111111101, (outs), (ins MEMii:$a), "ldaw r11, cp[$a]",
 626                       [(set R11, ADDRcpii:$a)]>;
 627
 628 defm SETSR : FU6_LU6_int<0b0111101101, "setsr", int_xcore_setsr>;
 629
 630 defm CLRSR : FU6_LU6_int<0b0111101100, "clrsr", int_xcore_clrsr>;
 631
 632 // setsr may cause a branch if it is used to enable events. clrsr may
 633 // branch if it is executed while events are enabled.
 634 let isBranch=1, isIndirectBranch=1, isTerminator=1, isBarrier = 1,
 635     isCodeGenOnly = 1 in {
 636 defm SETSR_branch : FU6_LU6_np<0b0111101101, "setsr">;
 637 defm CLRSR_branch : FU6_LU6_np<0b0111101100, "clrsr">;
 638 }
 639
 640 // U10
 641 // TODO ldwcpl, blacp
 642
 643 let Defs = [R11], isReMaterializable = 1, neverHasSideEffects = 1 in
 644 def LDAPF_u10 : _FU10<0b110110, (outs), (ins i32imm:$a), "ldap r11, $a", []>;
 645
 646 let Defs = [R11], isReMaterializable = 1 in
 647 def LDAPF_lu10 : _FLU10<0b110110, (outs), (ins i32imm:$a), "ldap r11, $a",
 648                         [(set R11, (pcrelwrapper tglobaladdr:$a))]>;
 649
 650 let Defs = [R11], isReMaterializable = 1, isCodeGenOnly = 1 in
 651 def LDAPF_lu10_ba : _FLU10<0b110110, (outs), (ins i32imm:$a), "ldap r11, $a",
 652                            [(set R11, (pcrelwrapper tblockaddress:$a))]>;
 653
 654 let isCall=1,
 655 // All calls clobber the link register and the non-callee-saved registers:
 656 Defs = [R0, R1, R2, R3, R11, LR], Uses = [SP] in {
 657 def BLRF_u10 : _FU10<0b110100, (outs), (ins calltarget:$a), "bl $a",
 658                      [(XCoreBranchLink immU10:$a)]>;
 659
 660 def BLRF_lu10 : _FLU10<0b110100, (outs), (ins calltarget:$a), "bl $a",
 661                        [(XCoreBranchLink immU20:$a)]>;
 662 }
 663
 664 // Two operand short
 665 // TODO eet, eef, tsetmr
 666 def NOT : _F2R<0b100010, (outs GRRegs:$dst), (ins GRRegs:$b),
 667                 "not $dst, $b", [(set GRRegs:$dst, (not GRRegs:$b))]>;
 668
 669 def NEG : _F2R<0b100100, (outs GRRegs:$dst), (ins GRRegs:$b),
 670                 "neg $dst, $b", [(set GRRegs:$dst, (ineg GRRegs:$b))]>;
 671
 672 let Constraints = "$src1 = $dst" in {
 673 def SEXT_rus :
 674   _FRUSSrcDstBitp<0b001101, (outs GRRegs:$dst), (ins GRRegs:$src1, i32imm:$src2),
 675                   "sext $dst, $src2",
 676                   [(set GRRegs:$dst, (int_xcore_sext GRRegs:$src1,
 677                                                      immBitp:$src2))]>;
 678
 679 def SEXT_2r :
 680   _F2RSrcDst<0b001100, (outs GRRegs:$dst), (ins GRRegs:$src1, GRRegs:$src2),
 681              "sext $dst, $src2",
 682              [(set GRRegs:$dst, (int_xcore_sext GRRegs:$src1, GRRegs:$src2))]>;
 683
 684 def ZEXT_rus :
 685   _FRUSSrcDstBitp<0b010001, (outs GRRegs:$dst), (ins GRRegs:$src1, i32imm:$src2),
 686                   "zext $dst, $src2",
 687                   [(set GRRegs:$dst, (int_xcore_zext GRRegs:$src1,
 688                                                      immBitp:$src2))]>;
 689
 690 def ZEXT_2r :
 691   _F2RSrcDst<0b010000, (outs GRRegs:$dst), (ins GRRegs:$src1, GRRegs:$src2),
 692              "zext $dst, $src2",
 693              [(set GRRegs:$dst, (int_xcore_zext GRRegs:$src1, GRRegs:$src2))]>;
 694
 695 def ANDNOT_2r :
 696   _F2RSrcDst<0b001010, (outs GRRegs:$dst), (ins GRRegs:$src1, GRRegs:$src2),
 697              "andnot $dst, $src2",
 698              [(set GRRegs:$dst, (and GRRegs:$src1, (not GRRegs:$src2)))]>;
 699 }
 700
 701 let isReMaterializable = 1, neverHasSideEffects = 1 in
 702 def MKMSK_rus : _FRUSBitp<0b101001, (outs GRRegs:$dst), (ins i32imm:$size),
 703                           "mkmsk $dst, $size", []>;
 704
 705 def MKMSK_2r : _F2R<0b101000, (outs GRRegs:$dst), (ins GRRegs:$size),
 706                     "mkmsk $dst, $size",
 707                     [(set GRRegs:$dst, (add (shl 1, GRRegs:$size), -1))]>;
 708
 709 def GETR_rus : _FRUS<0b100000, (outs GRRegs:$dst), (ins i32imm:$type),
 710                      "getr $dst, $type",
 711                      [(set GRRegs:$dst, (int_xcore_getr immUs:$type))]>;
 712
 713 def GETTS_2r : _F2R<0b001110, (outs GRRegs:$dst), (ins GRRegs:$r),
 714                     "getts $dst, res[$r]",
 715                     [(set GRRegs:$dst, (int_xcore_getts GRRegs:$r))]>;
 716
 717 def SETPT_2r : _FR2R<0b001111, (outs), (ins GRRegs:$r, GRRegs:$val),
 718                      "setpt res[$r], $val",
 719                      [(int_xcore_setpt GRRegs:$r, GRRegs:$val)]>;
 720
 721 def OUTCT_2r : _F2R<0b010010, (outs), (ins GRRegs:$r, GRRegs:$val),
 722                     "outct res[$r], $val",
 723                     [(int_xcore_outct GRRegs:$r, GRRegs:$val)]>;
 724
 725 def OUTCT_rus : _FRUS<0b010011, (outs), (ins GRRegs:$r, i32imm:$val),
 726                        "outct res[$r], $val",
 727                        [(int_xcore_outct GRRegs:$r, immUs:$val)]>;
 728
 729 def OUTT_2r : _FR2R<0b000011, (outs), (ins GRRegs:$r, GRRegs:$val),
 730                     "outt res[$r], $val",
 731                     [(int_xcore_outt GRRegs:$r, GRRegs:$val)]>;
 732
 733 def OUT_2r : _FR2R<0b101010, (outs), (ins GRRegs:$r, GRRegs:$val),
 734                    "out res[$r], $val",
 735                    [(int_xcore_out GRRegs:$r, GRRegs:$val)]>;
 736
 737 let Constraints = "$src = $dst" in
 738 def OUTSHR_2r :
 739   _F2RSrcDst<0b101011, (outs GRRegs:$dst), (ins GRRegs:$src, GRRegs:$r),
 740              "outshr res[$r], $src",
 741              [(set GRRegs:$dst, (int_xcore_outshr GRRegs:$r, GRRegs:$src))]>;
 742
 743 def INCT_2r : _F2R<0b100001, (outs GRRegs:$dst), (ins GRRegs:$r),
 744                    "inct $dst, res[$r]",
 745                    [(set GRRegs:$dst, (int_xcore_inct GRRegs:$r))]>;
 746
 747 def INT_2r : _F2R<0b100011, (outs GRRegs:$dst), (ins GRRegs:$r),
 748                   "int $dst, res[$r]",
 749                   [(set GRRegs:$dst, (int_xcore_int GRRegs:$r))]>;
 750
 751 def IN_2r : _F2R<0b101100, (outs GRRegs:$dst), (ins GRRegs:$r),
 752                  "in $dst, res[$r]",
 753                  [(set GRRegs:$dst, (int_xcore_in GRRegs:$r))]>;
 754
 755 let Constraints = "$src = $dst" in
 756 def INSHR_2r :
 757   _F2RSrcDst<0b101101, (outs GRRegs:$dst), (ins GRRegs:$src, GRRegs:$r),
 758              "inshr $dst, res[$r]",
 759              [(set GRRegs:$dst, (int_xcore_inshr GRRegs:$r, GRRegs:$src))]>;
 760
 761 def CHKCT_2r : _F2R<0b110010, (outs), (ins GRRegs:$r, GRRegs:$val),
 762                     "chkct res[$r], $val",
 763                     [(int_xcore_chkct GRRegs:$r, GRRegs:$val)]>;
 764
 765 def CHKCT_rus : _FRUSBitp<0b110011, (outs), (ins GRRegs:$r, i32imm:$val),
 766                           "chkct res[$r], $val",
 767                           [(int_xcore_chkct GRRegs:$r, immUs:$val)]>;
 768
 769 def TESTCT_2r : _F2R<0b101111, (outs GRRegs:$dst), (ins GRRegs:$src),
 770                      "testct $dst, res[$src]",
 771                      [(set GRRegs:$dst, (int_xcore_testct GRRegs:$src))]>;
 772
 773 def TESTWCT_2r : _F2R<0b110001, (outs GRRegs:$dst), (ins GRRegs:$src),
 774                       "testwct $dst, res[$src]",
 775                       [(set GRRegs:$dst, (int_xcore_testwct GRRegs:$src))]>;
 776
 777 def SETD_2r : _FR2R<0b000101, (outs), (ins GRRegs:$r, GRRegs:$val),
 778                     "setd res[$r], $val",
 779                     [(int_xcore_setd GRRegs:$r, GRRegs:$val)]>;
 780
 781 def SETPSC_2r : _FR2R<0b110000, (outs), (ins GRRegs:$src1, GRRegs:$src2),
 782                       "setpsc res[$src1], $src2",
 783                       [(int_xcore_setpsc GRRegs:$src1, GRRegs:$src2)]>;
 784
 785 def GETST_2r : _F2R<0b000001, (outs GRRegs:$dst), (ins GRRegs:$r),
 786                     "getst $dst, res[$r]",
 787                     [(set GRRegs:$dst, (int_xcore_getst GRRegs:$r))]>;
 788
 789 def INITSP_2r : _F2R<0b000100, (outs), (ins GRRegs:$src, GRRegs:$t),
 790                      "init t[$t]:sp, $src",
 791                      [(int_xcore_initsp GRRegs:$t, GRRegs:$src)]>;
 792
 793 def INITPC_2r : _F2R<0b000000, (outs), (ins GRRegs:$src, GRRegs:$t),
 794                      "init t[$t]:pc, $src",
 795                      [(int_xcore_initpc GRRegs:$t, GRRegs:$src)]>;
 796
 797 def INITCP_2r : _F2R<0b000110, (outs), (ins GRRegs:$src, GRRegs:$t),
 798                      "init t[$t]:cp, $src",
 799                      [(int_xcore_initcp GRRegs:$t, GRRegs:$src)]>;
 800
 801 def INITDP_2r : _F2R<0b000010, (outs), (ins GRRegs:$src, GRRegs:$t),
 802                      "init t[$t]:dp, $src",
 803                      [(int_xcore_initdp GRRegs:$t, GRRegs:$src)]>;
 804
 805 def PEEK_2r : _F2R<0b101110, (outs GRRegs:$dst), (ins GRRegs:$src),
 806                     "peek $dst, res[$src]",
 807                     [(set GRRegs:$dst, (int_xcore_peek GRRegs:$src))]>;
 808
 809 def ENDIN_2r : _F2R<0b100101, (outs GRRegs:$dst), (ins GRRegs:$src),
 810                      "endin $dst, res[$src]",
 811                      [(set GRRegs:$dst, (int_xcore_endin GRRegs:$src))]>;
 812
 813 // Two operand long
 814 def BITREV_l2r : _FL2R<0b0000011000, (outs GRRegs:$dst), (ins GRRegs:$src),
 815                        "bitrev $dst, $src",
 816                        [(set GRRegs:$dst, (int_xcore_bitrev GRRegs:$src))]>;
 817
 818 def BYTEREV_l2r : _FL2R<0b0000011001, (outs GRRegs:$dst), (ins GRRegs:$src),
 819                         "byterev $dst, $src",
 820                         [(set GRRegs:$dst, (bswap GRRegs:$src))]>;
 821
 822 def CLZ_l2r : _FL2R<0b000111000, (outs GRRegs:$dst), (ins GRRegs:$src),
 823                     "clz $dst, $src",
 824                     [(set GRRegs:$dst, (ctlz GRRegs:$src))]>;
 825
 826 def GETD_l2r : _FL2R<0b0001111001, (outs GRRegs:$dst), (ins GRRegs:$src),
 827                      "getd $dst, res[$src]", []>;
 828
 829 def GETN_l2r : _FL2R<0b0011011001, (outs GRRegs:$dst), (ins GRRegs:$src),
 830                      "getn $dst, res[$src]", []>;
 831
 832 def SETC_l2r : _FL2R<0b0010111001, (outs), (ins GRRegs:$r, GRRegs:$val),
 833                      "setc res[$r], $val",
 834                      [(int_xcore_setc GRRegs:$r, GRRegs:$val)]>;
 835
 836 def SETTW_l2r : _FLR2R<0b0010011001, (outs), (ins GRRegs:$r, GRRegs:$val),
 837                        "settw res[$r], $val",
 838                        [(int_xcore_settw GRRegs:$r, GRRegs:$val)]>;
 839
 840 def GETPS_l2r : _FL2R<0b0001011001, (outs GRRegs:$dst), (ins GRRegs:$src),
 841                       "get $dst, ps[$src]",
 842                       [(set GRRegs:$dst, (int_xcore_getps GRRegs:$src))]>;
 843
 844 def SETPS_l2r : _FLR2R<0b0001111000, (outs), (ins GRRegs:$src1, GRRegs:$src2),
 845                        "set ps[$src1], $src2",
 846                        [(int_xcore_setps GRRegs:$src1, GRRegs:$src2)]>;
 847
 848 def INITLR_l2r : _FL2R<0b0001011000, (outs), (ins GRRegs:$src, GRRegs:$t),
 849                        "init t[$t]:lr, $src",
 850                        [(int_xcore_initlr GRRegs:$t, GRRegs:$src)]>;
 851
 852 def SETCLK_l2r : _FLR2R<0b0000111001, (outs), (ins GRRegs:$src1, GRRegs:$src2),
 853                         "setclk res[$src1], $src2",
 854                         [(int_xcore_setclk GRRegs:$src1, GRRegs:$src2)]>;
 855
 856 def SETN_l2r : _FLR2R<0b0011011000, (outs), (ins GRRegs:$src1, GRRegs:$src2),
 857                       "setn res[$src1], $src2", []>;
 858
 859 def SETRDY_l2r : _FLR2R<0b0010111000, (outs), (ins GRRegs:$src1, GRRegs:$src2),
 860                         "setrdy res[$src1], $src2",
 861                         [(int_xcore_setrdy GRRegs:$src1, GRRegs:$src2)]>;
 862
 863 def TESTLCL_l2r : _FL2R<0b0010011000, (outs GRRegs:$dst), (ins GRRegs:$src),
 864                         "testlcl $dst, res[$src]", []>;
 865
 866 // One operand short
 867 def MSYNC_1r : _F1R<0b000111, (outs), (ins GRRegs:$a),
 868                     "msync res[$a]",
 869                     [(int_xcore_msync GRRegs:$a)]>;
 870 def MJOIN_1r : _F1R<0b000101, (outs), (ins GRRegs:$a),
 871                     "mjoin res[$a]",
 872                     [(int_xcore_mjoin GRRegs:$a)]>;
 873
 874 let isBranch=1, isIndirectBranch=1, isTerminator=1, isBarrier = 1 in
 875 def BAU_1r : _F1R<0b001001, (outs), (ins GRRegs:$a),
 876                  "bau $a",
 877                  [(brind GRRegs:$a)]>;
 878
 879 let isBranch=1, isIndirectBranch=1, isTerminator=1, isBarrier = 1 in
 880 def BR_JT : PseudoInstXCore<(outs), (ins InlineJT:$t, GRRegs:$i),
 881                             "bru $i\n$t",
 882                             [(XCoreBR_JT tjumptable:$t, GRRegs:$i)]>;
 883
 884 let isBranch=1, isIndirectBranch=1, isTerminator=1, isBarrier = 1 in
 885 def BR_JT32 : PseudoInstXCore<(outs), (ins InlineJT32:$t, GRRegs:$i),
 886                               "bru $i\n$t",
 887                               [(XCoreBR_JT32 tjumptable:$t, GRRegs:$i)]>;
 888
 889 let Defs=[SP], neverHasSideEffects=1 in
 890 def SETSP_1r : _F1R<0b001011, (outs), (ins GRRegs:$a), "set sp, $a", []>;
 891
 892 let neverHasSideEffects=1 in
 893 def SETDP_1r : _F1R<0b001100, (outs), (ins GRRegs:$a), "set dp, $a", []>;
 894
 895 let neverHasSideEffects=1 in
 896 def SETCP_1r : _F1R<0b001101, (outs), (ins GRRegs:$a), "set cp, $a", []>;
 897
 898 let hasCtrlDep = 1 in
 899 def ECALLT_1r : _F1R<0b010011, (outs), (ins GRRegs:$a),
 900                  "ecallt $a",
 901                  []>;
 902
 903 let hasCtrlDep = 1 in
 904 def ECALLF_1r : _F1R<0b010010, (outs), (ins GRRegs:$a),
 905                  "ecallf $a",
 906                  []>;
 907
 908 let isCall=1,
 909 // All calls clobber the link register and the non-callee-saved registers:
 910 Defs = [R0, R1, R2, R3, R11, LR], Uses = [SP] in {
 911 def BLA_1r : _F1R<0b001000, (outs), (ins GRRegs:$a),
 912                  "bla $a",
 913                  [(XCoreBranchLink GRRegs:$a)]>;
 914 }
 915
 916 def SYNCR_1r : _F1R<0b100001, (outs), (ins GRRegs:$a),
 917                  "syncr res[$a]",
 918                  [(int_xcore_syncr GRRegs:$a)]>;
 919
 920 def FREER_1r : _F1R<0b000100, (outs), (ins GRRegs:$a),
 921                "freer res[$a]",
 922                [(int_xcore_freer GRRegs:$a)]>;
 923
 924 let Uses=[R11] in {
 925 def SETV_1r : _F1R<0b010001, (outs), (ins GRRegs:$a),
 926                    "setv res[$a], r11",
 927                    [(int_xcore_setv GRRegs:$a, R11)]>;
 928
 929 def SETEV_1r : _F1R<0b001111, (outs), (ins GRRegs:$a),
 930                     "setev res[$a], r11",
 931                     [(int_xcore_setev GRRegs:$a, R11)]>;
 932 }
 933
 934 def DGETREG_1r : _F1R<0b001110, (outs GRRegs:$a), (ins), "dgetreg $a", []>;
 935
 936 def EDU_1r : _F1R<0b000000, (outs), (ins GRRegs:$a), "edu res[$a]", []>;
 937
 938 def EEU_1r : _F1R<0b000001, (outs), (ins GRRegs:$a),
 939                "eeu res[$a]",
 940                [(int_xcore_eeu GRRegs:$a)]>;
 941
 942 def KCALL_1r : _F1R<0b010000, (outs), (ins GRRegs:$a), "kcall $a", []>;
 943
 944 def WAITEF_1R : _F1R<0b000011, (outs), (ins GRRegs:$a), "waitef $a", []>;
 945
 946 def WAITET_1R : _F1R<0b000010, (outs), (ins GRRegs:$a), "waitet $a", []>;
 947
 948 def TSTART_1R : _F1R<0b000110, (outs), (ins GRRegs:$a), "start t[$a]", []>;
 949
 950 def CLRPT_1R : _F1R<0b100000, (outs), (ins GRRegs:$a), "clrpt res[$a]", []>;
 951
 952 // Zero operand short
 953
 954 def CLRE_0R : _F0R<0b0000001101, (outs), (ins), "clre", [(int_xcore_clre)]>;
 955
 956 def DCALL_0R : _F0R<0b0000011100, (outs), (ins), "dcall", []>;
 957
 958 let Defs = [SP], Uses = [SP] in
 959 def DENTSP_0R : _F0R<0b0001001100, (outs), (ins), "dentsp", []>;
 960
 961 let Defs = [SP] in
 962 def DRESTSP_0R : _F0R<0b0001001101, (outs), (ins), "drestsp", []>;
 963
 964 def DRET_0R : _F0R<0b0000011110, (outs), (ins), "dret", []>;
 965
 966 def FREET_0R : _F0R<0b0000001111, (outs), (ins), "freet", []>;
 967
 968 let Defs = [R11] in {
 969 def GETID_0R : _F0R<0b0001001110, (outs), (ins),
 970                     "get r11, id",
 971                     [(set R11, (int_xcore_getid))]>;
 972
 973 def GETED_0R : _F0R<0b0000111110, (outs), (ins),
 974                     "get r11, ed",
 975                     [(set R11, (int_xcore_geted))]>;
 976
 977 def GETET_0R : _F0R<0b0000111111, (outs), (ins),
 978                     "get r11, et",
 979                     [(set R11, (int_xcore_getet))]>;
 980
 981 def GETKEP_0R : _F0R<0b0001001111, (outs), (ins),
 982                      "get r11, kep", []>;
 983
 984 def GETKSP_0R : _F0R<0b0001011100, (outs), (ins),
 985                      "get r11, ksp", []>;
 986 }
 987
 988 let Defs = [SP] in
 989 def KRET_0R : _F0R<0b0000011101, (outs), (ins), "kret", []>;
 990
 991 let Uses = [SP], mayLoad = 1 in {
 992 def LDET_0R : _F0R<0b0001011110, (outs), (ins), "ldw et, sp[4]", []>;
 993
 994 def LDSED_0R : _F0R<0b0001011101, (outs), (ins), "ldw sed, sp[3]", []>;
 995
 996 def LDSPC_0R : _F0R<0b0000101100, (outs), (ins), "ldw spc, sp[1]", []>;
 997
 998 def LDSSR_0R : _F0R<0b0000101110, (outs), (ins), "ldw ssr, sp[2]", []>;
 999 }
1000
1001 let Uses=[R11] in
1002 def SETKEP_0R : _F0R<0b0000011111, (outs), (ins), "set kep, r11", []>;
1003
1004 def SSYNC_0r : _F0R<0b0000001110, (outs), (ins),
1005                     "ssync",
1006                     [(int_xcore_ssync)]>;
1007
1008 let Uses = [SP], mayStore = 1 in {
1009 def STET_0R : _F0R<0b0000111101, (outs), (ins), "stw et, sp[4]", []>;
1010
1011 def STSED_0R : _F0R<0b0000111100, (outs), (ins), "stw sed, sp[3]", []>;
1012
1013 def STSPC_0R : _F0R<0b0000101101, (outs), (ins), "stw spc, sp[1]", []>;
1014
1015 def STSSR_0R : _F0R<0b0000101111, (outs), (ins), "stw ssr, sp[2]", []>;
1016 }
1017
1018 let isBranch=1, isIndirectBranch=1, isTerminator=1, isBarrier = 1,
1019     hasSideEffects = 1 in
1020 def WAITEU_0R : _F0R<0b0000001100, (outs), (ins),
1021                      "waiteu",
1022                      [(brind (int_xcore_waitevent))]>;
1023
1024 //===----------------------------------------------------------------------===//
1025 // Non-Instruction Patterns
1026 //===----------------------------------------------------------------------===//
1027
1028 def : Pat<(XCoreBranchLink tglobaladdr:$addr), (BLRF_lu10 tglobaladdr:$addr)>;
1029 def : Pat<(XCoreBranchLink texternalsym:$addr), (BLRF_lu10 texternalsym:$addr)>;
1030
1031 /// sext_inreg
1032 def : Pat<(sext_inreg GRRegs:$b, i1), (SEXT_rus GRRegs:$b, 1)>;
1033 def : Pat<(sext_inreg GRRegs:$b, i8), (SEXT_rus GRRegs:$b, 8)>;
1034 def : Pat<(sext_inreg GRRegs:$b, i16), (SEXT_rus GRRegs:$b, 16)>;
1035
1036 /// loads
1037 def : Pat<(zextloadi8 (add GRRegs:$addr, GRRegs:$offset)),
1038           (LD8U_3r GRRegs:$addr, GRRegs:$offset)>;
1039 def : Pat<(zextloadi8 GRRegs:$addr), (LD8U_3r GRRegs:$addr, (LDC_ru6 0))>;
1040
1041 def : Pat<(sextloadi16 (lda16f GRRegs:$addr, GRRegs:$offset)),
1042           (LD16S_3r GRRegs:$addr, GRRegs:$offset)>;
1043 def : Pat<(sextloadi16 GRRegs:$addr), (LD16S_3r GRRegs:$addr, (LDC_ru6 0))>;
1044
1045 def : Pat<(load (ldawf GRRegs:$addr, GRRegs:$offset)),
1046           (LDW_3r GRRegs:$addr, GRRegs:$offset)>;
1047 def : Pat<(load (add GRRegs:$addr, immUs4:$offset)),
1048           (LDW_2rus GRRegs:$addr, (div4_xform immUs4:$offset))>;
1049 def : Pat<(load GRRegs:$addr), (LDW_2rus GRRegs:$addr, 0)>;
1050
1051 /// anyext
1052 def : Pat<(extloadi8 (add GRRegs:$addr, GRRegs:$offset)),
1053           (LD8U_3r GRRegs:$addr, GRRegs:$offset)>;
1054 def : Pat<(extloadi8 GRRegs:$addr), (LD8U_3r GRRegs:$addr, (LDC_ru6 0))>;
1055 def : Pat<(extloadi16 (lda16f GRRegs:$addr, GRRegs:$offset)),
1056           (LD16S_3r GRRegs:$addr, GRRegs:$offset)>;
1057 def : Pat<(extloadi16 GRRegs:$addr), (LD16S_3r GRRegs:$addr, (LDC_ru6 0))>;
1058
1059 /// stores
1060 def : Pat<(truncstorei8 GRRegs:$val, (add GRRegs:$addr, GRRegs:$offset)),
1061           (ST8_l3r GRRegs:$val, GRRegs:$addr, GRRegs:$offset)>;
1062 def : Pat<(truncstorei8 GRRegs:$val, GRRegs:$addr),
1063           (ST8_l3r GRRegs:$val, GRRegs:$addr, (LDC_ru6 0))>;
1064
1065 def : Pat<(truncstorei16 GRRegs:$val, (lda16f GRRegs:$addr, GRRegs:$offset)),
1066           (ST16_l3r GRRegs:$val, GRRegs:$addr, GRRegs:$offset)>;
1067 def : Pat<(truncstorei16 GRRegs:$val, GRRegs:$addr),
1068           (ST16_l3r GRRegs:$val, GRRegs:$addr, (LDC_ru6 0))>;
1069
1070 def : Pat<(store GRRegs:$val, (ldawf GRRegs:$addr, GRRegs:$offset)),
1071           (STW_l3r GRRegs:$val, GRRegs:$addr, GRRegs:$offset)>;
1072 def : Pat<(store GRRegs:$val, (add GRRegs:$addr, immUs4:$offset)),
1073           (STW_2rus GRRegs:$val, GRRegs:$addr, (div4_xform immUs4:$offset))>;
1074 def : Pat<(store GRRegs:$val, GRRegs:$addr),
1075           (STW_2rus GRRegs:$val, GRRegs:$addr, 0)>;
1076
1077 /// cttz
1078 def : Pat<(cttz GRRegs:$src), (CLZ_l2r (BITREV_l2r GRRegs:$src))>;
1079
1080 /// trap
1081 def : Pat<(trap), (ECALLF_1r (LDC_ru6 0))>;
1082
1083 ///
1084 /// branch patterns
1085 ///
1086
1087 // unconditional branch
1088 def : Pat<(br bb:$addr), (BRFU_lu6 bb:$addr)>;
1089
1090 // direct match equal/notequal zero brcond
1091 def : Pat<(brcond (setne GRRegs:$lhs, 0), bb:$dst),
1092           (BRFT_lru6 GRRegs:$lhs, bb:$dst)>;
1093 def : Pat<(brcond (seteq GRRegs:$lhs, 0), bb:$dst),
1094           (BRFF_lru6 GRRegs:$lhs, bb:$dst)>;
1095
1096 def : Pat<(brcond (setle GRRegs:$lhs, GRRegs:$rhs), bb:$dst),
1097           (BRFF_lru6 (LSS_3r GRRegs:$rhs, GRRegs:$lhs), bb:$dst)>;
1098 def : Pat<(brcond (setule GRRegs:$lhs, GRRegs:$rhs), bb:$dst),
1099           (BRFF_lru6 (LSU_3r GRRegs:$rhs, GRRegs:$lhs), bb:$dst)>;
1100 def : Pat<(brcond (setge GRRegs:$lhs, GRRegs:$rhs), bb:$dst),
1101           (BRFF_lru6 (LSS_3r GRRegs:$lhs, GRRegs:$rhs), bb:$dst)>;
1102 def : Pat<(brcond (setuge GRRegs:$lhs, GRRegs:$rhs), bb:$dst),
1103           (BRFF_lru6 (LSU_3r GRRegs:$lhs, GRRegs:$rhs), bb:$dst)>;
1104 def : Pat<(brcond (setne GRRegs:$lhs, GRRegs:$rhs), bb:$dst),
1105           (BRFF_lru6 (EQ_3r GRRegs:$lhs, GRRegs:$rhs), bb:$dst)>;
1106 def : Pat<(brcond (setne GRRegs:$lhs, immUs:$rhs), bb:$dst),
1107           (BRFF_lru6 (EQ_2rus GRRegs:$lhs, immUs:$rhs), bb:$dst)>;
1108
1109 // generic brcond pattern
1110 def : Pat<(brcond GRRegs:$cond, bb:$addr), (BRFT_lru6 GRRegs:$cond, bb:$addr)>;
1111
1112
1113 ///
1114 /// Select patterns
1115 ///
1116
1117 // direct match equal/notequal zero select
1118 def : Pat<(select (setne GRRegs:$lhs, 0), GRRegs:$T, GRRegs:$F),
1119         (SELECT_CC GRRegs:$lhs, GRRegs:$T, GRRegs:$F)>;
1120
1121 def : Pat<(select (seteq GRRegs:$lhs, 0), GRRegs:$T, GRRegs:$F),
1122         (SELECT_CC GRRegs:$lhs, GRRegs:$F, GRRegs:$T)>;
1123
1124 def : Pat<(select (setle GRRegs:$lhs, GRRegs:$rhs), GRRegs:$T, GRRegs:$F),
1125           (SELECT_CC (LSS_3r GRRegs:$rhs, GRRegs:$lhs), GRRegs:$F, GRRegs:$T)>;
1126 def : Pat<(select (setule GRRegs:$lhs, GRRegs:$rhs), GRRegs:$T, GRRegs:$F),
1127           (SELECT_CC (LSU_3r GRRegs:$rhs, GRRegs:$lhs), GRRegs:$F, GRRegs:$T)>;
1128 def : Pat<(select (setge GRRegs:$lhs, GRRegs:$rhs), GRRegs:$T, GRRegs:$F),
1129           (SELECT_CC (LSS_3r GRRegs:$lhs, GRRegs:$rhs), GRRegs:$F, GRRegs:$T)>;
1130 def : Pat<(select (setuge GRRegs:$lhs, GRRegs:$rhs), GRRegs:$T, GRRegs:$F),
1131           (SELECT_CC (LSU_3r GRRegs:$lhs, GRRegs:$rhs), GRRegs:$F, GRRegs:$T)>;
1132 def : Pat<(select (setne GRRegs:$lhs, GRRegs:$rhs), GRRegs:$T, GRRegs:$F),
1133           (SELECT_CC (EQ_3r GRRegs:$lhs, GRRegs:$rhs), GRRegs:$F, GRRegs:$T)>;
1134 def : Pat<(select (setne GRRegs:$lhs, immUs:$rhs), GRRegs:$T, GRRegs:$F),
1135           (SELECT_CC (EQ_2rus GRRegs:$lhs, immUs:$rhs), GRRegs:$F, GRRegs:$T)>;
1136
1137 ///
1138 /// setcc patterns, only matched when none of the above brcond
1139 /// patterns match
1140 ///
1141
1142 // setcc 2 register operands
1143 def : Pat<(setle GRRegs:$lhs, GRRegs:$rhs),
1144           (EQ_2rus (LSS_3r GRRegs:$rhs, GRRegs:$lhs), 0)>;
1145 def : Pat<(setule GRRegs:$lhs, GRRegs:$rhs),
1146           (EQ_2rus (LSU_3r GRRegs:$rhs, GRRegs:$lhs), 0)>;
1147
1148 def : Pat<(setgt GRRegs:$lhs, GRRegs:$rhs),
1149           (LSS_3r GRRegs:$rhs, GRRegs:$lhs)>;
1150 def : Pat<(setugt GRRegs:$lhs, GRRegs:$rhs),
1151           (LSU_3r GRRegs:$rhs, GRRegs:$lhs)>;
1152
1153 def : Pat<(setge GRRegs:$lhs, GRRegs:$rhs),
1154           (EQ_2rus (LSS_3r GRRegs:$lhs, GRRegs:$rhs), 0)>;
1155 def : Pat<(setuge GRRegs:$lhs, GRRegs:$rhs),
1156           (EQ_2rus (LSU_3r GRRegs:$lhs, GRRegs:$rhs), 0)>;
1157
1158 def : Pat<(setlt GRRegs:$lhs, GRRegs:$rhs),
1159           (LSS_3r GRRegs:$lhs, GRRegs:$rhs)>;
1160 def : Pat<(setult GRRegs:$lhs, GRRegs:$rhs),
1161           (LSU_3r GRRegs:$lhs, GRRegs:$rhs)>;
1162
1163 def : Pat<(setne GRRegs:$lhs, GRRegs:$rhs),
1164           (EQ_2rus (EQ_3r GRRegs:$lhs, GRRegs:$rhs), 0)>;
1165
1166 def : Pat<(seteq GRRegs:$lhs, GRRegs:$rhs),
1167           (EQ_3r GRRegs:$lhs, GRRegs:$rhs)>;
1168
1169 // setcc reg/imm operands
1170 def : Pat<(seteq GRRegs:$lhs, immUs:$rhs),
1171           (EQ_2rus GRRegs:$lhs, immUs:$rhs)>;
1172 def : Pat<(setne GRRegs:$lhs, immUs:$rhs),
1173           (EQ_2rus (EQ_2rus GRRegs:$lhs, immUs:$rhs), 0)>;
1174
1175 // misc
1176 def : Pat<(add GRRegs:$addr, immUs4:$offset),
1177           (LDAWF_l2rus GRRegs:$addr, (div4_xform immUs4:$offset))>;
1178
1179 def : Pat<(sub GRRegs:$addr, immUs4:$offset),
1180           (LDAWB_l2rus GRRegs:$addr, (div4_xform immUs4:$offset))>;
1181
1182 def : Pat<(and GRRegs:$val, immMskBitp:$mask),
1183           (ZEXT_rus GRRegs:$val, (msksize_xform immMskBitp:$mask))>;
1184
1185 // (sub X, imm) gets canonicalized to (add X, -imm).  Match this form.
1186 def : Pat<(add GRRegs:$src1, immUsNeg:$src2),
1187           (SUB_2rus GRRegs:$src1, (neg_xform immUsNeg:$src2))>;
1188
1189 def : Pat<(add GRRegs:$src1, immUs4Neg:$src2),
1190           (LDAWB_l2rus GRRegs:$src1, (div4neg_xform immUs4Neg:$src2))>;
1191
1192 ///
1193 /// Some peepholes
1194 ///
1195
1196 def : Pat<(mul GRRegs:$src, 3),
1197           (LDA16F_l3r GRRegs:$src, GRRegs:$src)>;
1198
1199 def : Pat<(mul GRRegs:$src, 5),
1200           (LDAWF_l3r GRRegs:$src, GRRegs:$src)>;
1201
1202 def : Pat<(mul GRRegs:$src, -3),
1203           (LDAWB_l3r GRRegs:$src, GRRegs:$src)>;
1204
1205 // ashr X, 32 is equivalent to ashr X, 31 on the XCore.
1206 def : Pat<(sra GRRegs:$src, 31),
1207           (ASHR_l2rus GRRegs:$src, 32)>;
1208
1209 def : Pat<(brcond (setlt GRRegs:$lhs, 0), bb:$dst),
1210           (BRFT_lru6 (ASHR_l2rus GRRegs:$lhs, 32), bb:$dst)>;
1211
1212 // setge X, 0 is canonicalized to setgt X, -1
1213 def : Pat<(brcond (setgt GRRegs:$lhs, -1), bb:$dst),
1214           (BRFF_lru6 (ASHR_l2rus GRRegs:$lhs, 32), bb:$dst)>;
1215
1216 def : Pat<(select (setlt GRRegs:$lhs, 0), GRRegs:$T, GRRegs:$F),
1217           (SELECT_CC (ASHR_l2rus GRRegs:$lhs, 32), GRRegs:$T, GRRegs:$F)>;
1218
1219 def : Pat<(select (setgt GRRegs:$lhs, -1), GRRegs:$T, GRRegs:$F),
1220           (SELECT_CC (ASHR_l2rus GRRegs:$lhs, 32), GRRegs:$F, GRRegs:$T)>;
1221
1222 def : Pat<(setgt GRRegs:$lhs, -1),
1223           (EQ_2rus (ASHR_l2rus GRRegs:$lhs, 32), 0)>;
1224
1225 def : Pat<(sra (shl GRRegs:$src, immBpwSubBitp:$imm), immBpwSubBitp:$imm),
1226           (SEXT_rus GRRegs:$src, (bpwsub_xform immBpwSubBitp:$imm))>;