1 @REM ******************************************************************************\r
2 @REM * FILE PURPOSE: Environment Setup for building PDK\r
3 @REM ******************************************************************************\r
4 @REM * FILE NAME: pdksetupenv.bat\r
5 @REM *\r
6 @REM * DESCRIPTION:\r
7 @REM * Configures and sets up the Build Environment for PDK.\r
8 @REM *\r
9 @REM * The batch file expects an optional argument:PDK_INSTALL_PATH: Location\r
10 @REM * of the PDK package. If the argument is not specified the batch file\r
11 @REM * assumes that the PDK is installed in the same location where the batch\r
12 @REM * file is located and is being executed.\r
13 @REM *\r
14 @REM * USAGE:\r
15 @REM * pdksetupenv.bat "C:\ti\pdk_<device>_<version>\packages"\r
16 @REM * --- OR ---\r
17 @REM * pdksetupenv.bat\r
18 @REM *\r
19 @REM * Copyright (C) 2012-2019, Texas Instruments, Inc.\r
20 @REM *****************************************************************************\r
21 @echo off\r
22 @REM *******************************************************************************\r
23 @REM ********************** GET PARAMETERS PASSED THROUGH ARGUMENT ***************\r
24 @REM *******************************************************************************\r
25 @REM Parameter Validation: Check if the argument was passed to the batch file and\r
26 @REM if so we use that else we default to the working directory where the batch\r
27 @REM file was invoked from\r
28 \r
29 @REM PDK_INSTALL_PATH if it is passed as an argument.\r
30 set pdk_path=%1\r
31 \r
32 set PDK_INSTALL_PATH=%CD%\r
33 \r
34 if defined pdk_path (\r
35 @REM Use the PDK install path if passed as an argument\r
36 set PDK_INSTALL_PATH=%pdk_path%\r
37 )\r
38 \r
39 @REM Find the PDK_SOC/PDK_VER by going to the procsdk\pdk directory.\r
40 cd %PDK_INSTALL_PATH%\..\r
41 \r
42 set s=%CD:\= %\r
43 for %%a in (%s%) do (\r
44 set pdkdir=%%a\r
45 )\r
46 for /f "tokens=1,2,3,4,5 delims=/_" %%a in ("%pdkdir%") do set pdksoc=%%b&set v1=%%c&set v2=%%d&set v3=%%e\r
47 set pdkdir_ver=%v1%_%v2%_%v3%\r
48 \r
49 @REM When pdk folder represents a device family, set a default SOC for that family\r
50 if %pdksoc% == jacinto (\r
51 set pdksoc=j721e\r
52 )\r
53 \r
54 @REM Go to the SDK install directory\r
55 cd %PDK_INSTALL_PATH%\..\..\r
56 \r
57 @REM Find the SDK directory to set SDK_INSTALL_PATH if it is not already set\r
58 set sdkdir=%CD:\=/%\r
59 \r
60 if not defined SDK_INSTALL_PATH (\r
61 set SDK_INSTALL_PATH=%sdkdir%\r
62 )\r
63 \r
64 @REM PDK SoC and version\r
65 if not defined PDK_SOC (\r
66 set PDK_SOC=%pdksoc%\r
67 )\r
68 \r
69 if not defined PDK_VERSION (\r
70 set PDK_VERSION=%pdkdir_ver%\r
71 )\r
72 \r
73 @REM return to the original directory (pdk_*/packages)\r
74 cd %PDK_INSTALL_PATH%\r
75 \r
76 @REM Find the XDC version from pdk/packages/ti/build/pdk_tools_path.mk\r
77 for /f %%i IN ('findstr "XDC_VERSION=" %PDK_INSTALL_PATH%\ti\build\pdk_tools_path.mk') do set xdcver=%%i\r
78 for /f "tokens=1,2 delims=//=" %%a in ("%xdcver%") do set XDC_VERSION=%%b\r
79 \r
80 if not defined GMAKE_INSTALL_PATH (\r
81 set GMAKE_INSTALL_PATH=%SDK_INSTALL_PATH%/xdctools_%XDC_VERSION%\r
82 )\r
83 set GMAKE_INSTALL_PATH=%GMAKE_INSTALL_PATH:\=/%\r
84 @REM GMAKE Tool location; Uncomment the following line to set the\r
85 @REM gmake install path into env PATH variable.\r
86 set PATH=%GMAKE_INSTALL_PATH:/=\%;%PATH%\r
87 \r
88 set PDK_INSTALL_PATH=%PDK_INSTALL_PATH:\=/%\r
89 @REM Define Rules.make\r
90 set RULES_MAKE=%PDK_INSTALL_PATH%/ti/build/Rules.make\r
91 \r
92 @REM Print the environmental variables\r
93 @echo ***************************************************\r
94 @echo Environment Configuration:\r
95 @echo ***************************************************\r
96 @echo SDK_INSTALL_PATH : %SDK_INSTALL_PATH%\r
97 @echo PDK_INSTALL_PATH : %PDK_INSTALL_PATH%\r
98 @echo GMAKE_INSTALL_PATH : %GMAKE_INSTALL_PATH%\r
99 @echo PDK_SOC : %PDK_SOC%\r
100 @echo PDK_VERSION : %PDK_VERSION%\r
101 @echo RULES_MAKE : %RULES_MAKE%\r
102 @echo ***************************************************\r