build_all.bat

   1 @echo off
   2 :: *************************************************************************
   3 ::  FILE           : build_all.bat
   4 ::  DESCRIPTION    :
   5 ::
   6 ::      Builds all for Dolby Harmony project for DA10x. This includes:
   7 ::          (1) ARM/DSP PAF libraries
   8 ::          (2) ARM/DSP Atmos component libraries: BMDA, CAR, DDP, MAT-THD, OAR
   9 ::          (3) DSP PDK LLD libraries: UART, SPI, I2C
  10 ::          (4) DSP PDK platform library
  11 ::          (5) ARM/DSP applications
  12 ::      Creates .zip packages for Atmos component libraries.
  13 ::
  14 :: *************************************************************************
  15
  16 @echo Executing:  %~fn0 %1 %2
  17
  18 :: *************************************************************************
  19 :: *** Check command line input
  20 :: *************************************************************************
  21 if "%1"=="" goto use_err1
  22 if "%2"=="" goto use_err1
  23 goto cont1
  24
  25
  26 :use_err1
  27 :: USAGE ERROR
  28 echo ERROR: Supplied options are invalid.
  29 echo .
  30 echo . Usage: %0 SuperRepo ^<buildProfile^>
  31 echo . -OR-
  32 echo . Usage: %0 ^<buildTag^> ^<buildProfile^>
  33 echo .
  34 echo .     SuperRepo        : Use Git super-repository to track submodules for build targets
  35 echo .     buildTag         : Use Git tag to track submodules for build targets
  36 echo .     buildProfile     : Debug, Release, or SDF
  37 echo .
  38 goto end
  39
  40
  41 :cont1
  42 set PASDK_ROOT_DIR=%~dp0
  43
  44
  45 if "%2" NEQ "SDF" goto install_tools
  46 :: Set PASDK target and version
  47 set PASDK_TARGET_PLATFORM=da10x
  48 set PASDK_VERSION=01_00_00_02
  49 :: Set FD package version
  50 set FD_PKG_VERSION=01_00_00_02
  51
  52 :: Set release directory
  53 set RELEASE_DIR=%PASDK_ROOT_DIR%release
  54 :: Set DH-IP package directory
  55 set DHIP_PKG_DIR=%RELEASE_DIR%\dhip_package
  56 :: Set FD package directory
  57 set FD_PKG_DIR=%RELEASE_DIR%\fd_package
  58 :: Set OS package directory
  59 set OS_PKG_DIR=%RELEASE_DIR%\os_package
  60
  61 if exist %RELEASE_DIR%\nul ( rmdir /S / Q %RELEASE_DIR% )
  62
  63
  64 :install_tools
  65 :: *************************************************************************
  66 :: *** Install tools
  67 :: *************************************************************************
  68 :: FL: tool installation not yet supported
  69 ::@call scripts\install_tools.bat
  70 @call scripts\setup_env.bat
  71
  72 :: *************************************************************************
  73 :: *** Install code
  74 :: *************************************************************************
  75 @call scripts\install_code.bat %1
  76
  77 :: *************************************************************************
  78 :: *** Build
  79 :: *************************************************************************
  80 :: Build ARM/DSP PAF libraries
  81 @pushd scripts
  82 @call build_paf_libs.bat
  83 @popd
  84
  85 :: Build ARM/DSP Atmos component libraries
  86 @pushd scripts
  87 @call build_alg_libs.bat
  88 @popd
  89
  90 :: Build DSP PDK LLD libraries
  91 @pushd scripts
  92 @call build_pdk_libs.bat
  93 @popd
  94 :: FL: brute force reset PDK environment setup. Clean this up later.
  95 @call scripts\setup_env.bat
  96
  97 if "%2" NEQ "SDF" goto build_ccs_projects
  98 :: Build DH-IP packages
  99 @pushd scripts
 100 @call build_dhip_pkgs %DHIP_PKG_DIR%
 101 @popd
 102
 103 :build_ccs_projects
 104 :: Build DSP PDK platform library, ARM/DSP applications
 105 @pushd scripts
 106 @call build_ccs_projects.bat %2 %DHIP_PKG_DIR%
 107 @popd
 108
 109 if "%2" NEQ "SDF" goto cleanupenv
 110 :: Build FD package
 111 @pushd scripts
 112 @call build_fd_pkg.bat %FD_PKG_DIR%
 113 @popd
 114
 115 :: Build OS package
 116 @pushd scripts
 117 @call build_os_pkg.bat %OS_PKG_DIR%
 118 @popd
 119
 120
 121 :cleanupenv
 122 set PASDK_ROOT_DIR=
 123 set PASDK_TARGET_PLATFORM=
 124 set PASDK_VERSION=
 125 set FD_PKG_VERSION=
 126 set RELEASE_DIR=
 127 set DHIP_PKG_DIR=
 128 set FD_PKG_DIR=
 129 set OS_PKG_DIR=
 130
 131
 132 :end