1 @REM ******************************************************************************
2 @REM * FILE PURPOSE: PDK Unit Test and Example Project Creator
3 @REM ******************************************************************************
4 @REM * FILE NAME: pdkProjectCreate.bat
5 @REM *
6 @REM * DESCRIPTION:
7 @REM * The script file is used to create the test and example projects of all
8 @REM * components under PDK. These projects are available in the specified
9 @REM * workspace.
10 @REM *
11 @REM * Syntax:
12 @REM * pdkProjectCreate.bat [soc] [board] [endian] [module] [processor] [pdkDir]
13 @REM *
14 @REM * Description: (first option is default)
15 @REM * soc - AM335x / AM437x / AM571x / AM572x / K2E / K2G / K2K / K2H / K2L /
16 @REM * C6678 / C6657
17 @REM * board - all (use "all" for K2X and C66X SOCs)
18 @REM * -or-
19 @REM * Refer to pdk_<soc>_<version>\packages\ti\board\lib
20 @REM * for valid board inputs for the soc
21 @REM * endian - little / big
22 @REM * module - all
23 @REM * -or-
24 @REM * aif2 / bcp / cppi / csl / dfe / emac / fatfs / fm / fftc /
25 @REM * gpio / hyplnk / i2c / icss_emac / iqn2 / mcasp / mcbsp / mmcsd / nimu /
26 @REM * nimu_icss / nwal / pa / pcie / pktlib / pruss / qmss / rm / sa /
27 @REM * serdes-diag / spi / srio / tcp3d / tfw / transportqmss /
28 @REM * transportsrio / tsip / uart / usb / wdtimer
29 @REM * processor - arm / dsp / m4
30 @REM * pdkDir - THIS FILE LOCATION / "C:\ti\pdk_<soc>_<version>\packages"
31 @REM *
32 @REM * Example:
33 @REM * a) pdkProjectCreate.bat
34 @REM * - Creates all module projects for the AM335x soc for arm little endian
35 @REM * b) pdkProjectCreate.bat AM437x
36 @REM * - Creates all module projects for the AM437x soc for arm little endian
37 @REM * c) pdkProjectCreate.bat AM437x idkAM437x
38 @REM * - Creates all module projects for idkAM437x device for arm little endian
39 @REM * d) pdkProjectCreate.bat AM571x evmAM571x little
40 @REM * - Creates all module projects for evmAM571x device for arm little endian
41 @REM * e) pdkProjectCreate.bat AM571x evmAM571x little i2c dsp
42 @REM * - Creates i2c module projects for evmAM571x device for dsp little endian
43 @REM * f) pdkProjectCreate.bat K2H all little i2c arm
44 @REM * - Creates i2c module projects for K2H device for arm little endian
45 @REM * g) pdkProjectCreate.bat C6678 all little hyplnk dsp
46 @REM * - Creates hyplnk module projects for C6678 device for dsp little endian
47 @REM *
48 @REM * Copyright (C) 2012-2016, Texas Instruments, Inc.
49 @REM *****************************************************************************
50 @echo OFF
52 REM Lists of valid input parameters - MUST be updated as new input parameters are added
53 REM *****************************************************************************
54 set soc_list=AM335x AM437x AM571x AM572x K2E K2K K2H K2L K2G C6678 C6657
55 set endian_list=little big
56 set module_list=all aif2 bcp cppi csl dfe emac fatfs fm fftc gpio hyplnk i2c icss_emac iqn2 mcasp mcbsp mmcsd nimu nimu_icss nwal pa pcie pktlib pruss qmss rm sa serdes_diag spi srio tcp3d tfw transportqmss transportsrio tsip uart usb wdtimer
57 set proc_list=arm dsp m4
59 REM Parameter Validation: Check if the argument was passed to the batch file.
60 REM *****************************************************************************
61 REM Argument [soc] is used to set SOC variable.
62 set tempVar1=%1
63 if not defined tempVar1 goto nosoc
64 set SOC=%tempVar1%
65 goto socdone
66 :nosoc
67 set SOC=AM335x
68 :socdone
70 REM Argument [board] is used to set BOARD variable.
71 REM This is the board type of the soc for which project are to be created.
72 set tempVar2=%2
73 if not defined tempVar2 goto noboard
74 set BOARD=%tempVar2%
75 goto boarddone
76 :noboard
77 set BOARD=all
78 :boarddone
80 REM Argument [endian] is used to set ENDIAN variable.
81 REM This is Endianess of the projects being created.
82 REM Valid Values are 'little' and 'big'. Defaults to 'little'.
83 set tempVar3=%3
84 if not defined tempVar3 goto littleendian
85 set ENDIAN=%tempVar3%
86 goto endiandone
87 :littleendian
88 set ENDIAN=little
89 :endiandone
91 REM Argument [module] is used to set MODULE variable.
92 REM This is specific module for which projects are created.
93 REM Valid Values are LLD name. Defaults to all LLD's.
94 set tempVar4=%4
95 if not defined tempVar4 goto nomodule
96 set MODULE=%tempVar4%
97 goto moduledone
98 :nomodule
99 set MODULE=all
100 :moduledone
102 REM Argument [processor] is used to set PROCESSOR variable.
103 REM This is specific processor type for which projects are created.
104 REM Valid Values are arm, dsp, or m4 . Defaults to arm.
105 set tempVar5=%5
106 if not defined tempVar5 goto noprocessor
107 set PROCESSOR=%tempVar5%
108 goto processordone
109 :noprocessor
110 set PROCESSOR=arm
111 :processordone
113 REM Argument [pdkDir] is used to set PDK_SHORT_NAME. This is PDK directory
114 REM where project description files are located. If there is no value passed,
115 REM it defaults to the file location directory. Then convert the variable to
116 REM short name to avoid issues using batch file commands.
117 set tempVar6=%6
118 if not defined tempVar6 goto noparameter
119 set PDK_SHORT_NAME=%tempVar6%
120 goto done
121 :noparameter
122 set PDK_SHORT_NAME=%~sdp0
123 :done
125 REM *****************************************************************************
127 echo =========================================================================
128 echo Configuration:
129 echo. SOC : %SOC%
130 echo BOARD : %BOARD%
131 echo. ENDIAN : %ENDIAN%
132 echo. MODULE : %MODULE%
133 echo. PROCESSOR : %PROCESSOR%
134 echo. PDK_SHORT_NAME : %PDK_SHORT_NAME%
135 echo =========================================================================
136 echo Checking Configuration...
138 for %%a in (%soc_list%) do (
139 if %SOC% == %%a (
140 goto end_soc_check
141 )
142 )
143 echo ERROR: SOC (%SOC%) is invalid
144 goto CONFIG_ERR
145 :end_soc_check
147 if %BOARD% == all (
148 goto end_board_check
149 )
150 setlocal enabledelayedexpansion
151 set board_type=!BOARD:%SOC%=!
152 if not %board_type% == %BOARD% (
153 goto end_board_check
154 )
155 echo ERROR: Board (%BOARD%) is invalid for the specified SOC (%SOC%)
156 goto CONFIG_ERR
157 :end_board_check
159 for %%a in (%endian_list%) do (
160 if %ENDIAN% == %%a (
161 goto end_endian_check
162 )
163 )
164 echo ERROR: Endian (%ENDIAN%) is invalid
165 goto CONFIG_ERR
166 :end_endian_check
168 for %%a in (%module_list%) do (
169 if %MODULE% == %%a (
170 goto end_module_check
171 )
172 )
173 echo ERROR: Module (%MODULE%) is invalid
174 goto CONFIG_ERR
175 :end_module_check
177 for %%a in (%proc_list%) do (
178 if %PROCESSOR% == %%a (
179 goto end_proc_check
180 )
181 )
182 echo ERROR: Processor (%PROCESSOR%) is invalid
183 goto CONFIG_ERR
184 :end_proc_check
186 if %SOC% == AM335x (
187 if %PROCESSOR% == dsp (
188 echo ERROR: The AM335x soc does not contain a DSP processor
189 goto CONFIG_ERR
190 ) else if %PROCESSOR% == m4 (
191 echo ERROR: The AM335x soc does not contain a M4 processor
192 goto CONFIG_ERR
193 )
195 if %ENDIAN% == big (
196 echo ERROR: The AM335x soc's arm does not support big endian
197 goto CONFIG_ERR
198 )
199 ) else if %SOC% == AM437x (
200 if %PROCESSOR% == dsp (
201 echo ERROR: The AM437x soc does not contain a DSP processor
202 goto CONFIG_ERR
203 ) else if %PROCESSOR% == m4 (
204 echo ERROR: The AM437x soc does not contain a M4 processor
205 goto CONFIG_ERR
206 )
208 if %ENDIAN% == big (
209 echo ERROR: The AM437x soc's arm does not support big endian
210 goto CONFIG_ERR
211 )
212 ) else if %SOC% == AM571x (
213 if %ENDIAN% == big (
214 echo ERROR: The AM571x soc's processor's do not support big endian
215 goto CONFIG_ERR
216 )
217 ) else if %SOC% == AM572x (
218 if %ENDIAN% == big (
219 echo ERROR: The AM572x soc's processor's do not support big endian
220 goto CONFIG_ERR
221 )
222 ) else if %SOC% == K2K (
223 if %PROCESSOR% == m4 (
224 echo ERROR: The K2K soc does not contain a M4 processor
225 goto CONFIG_ERR
226 )
228 if %PROCESSOR% == arm (
229 if %ENDIAN% == big (
230 echo ERROR: The K2K soc's arm does not support big endian
231 goto CONFIG_ERR
232 )
233 )
234 ) else if %SOC% == K2H (
235 if %PROCESSOR% == m4 (
236 echo ERROR: The K2H soc does not contain a M4 processor
237 goto CONFIG_ERR
238 )
240 if %PROCESSOR% == arm (
241 if %ENDIAN% == big (
242 echo ERROR: The K2H soc's arm does not support big endian
243 goto CONFIG_ERR
244 )
245 )
246 ) else if %SOC% == K2E (
247 if %PROCESSOR% == m4 (
248 echo ERROR: The K2E soc does not contain a M4 processor
249 goto CONFIG_ERR
250 )
252 if %PROCESSOR% == arm (
253 if %ENDIAN% == big (
254 echo ERROR: The K2E soc's arm does not support big endian
255 goto CONFIG_ERR
256 )
257 )
258 ) else if %SOC% == K2L (
259 if %PROCESSOR% == m4 (
260 echo ERROR: The K2L soc does not contain a M4 processor
261 goto CONFIG_ERR
262 )
264 if %PROCESSOR% == arm (
265 if %ENDIAN% == big (
266 echo ERROR: The K2L soc's arm does not support big endian
267 goto CONFIG_ERR
268 )
269 )
270 ) else if %SOC% == K2G (
271 if %PROCESSOR% == m4 (
272 echo ERROR: The K2G soc does not contain a M4 processor
273 goto CONFIG_ERR
274 )
276 if %PROCESSOR% == arm (
277 if %ENDIAN% == big (
278 echo ERROR: The K2G soc's arm does not support big endian
279 goto CONFIG_ERR
280 )
281 )
282 ) else if %SOC% == C6678 (
283 if %PROCESSOR% == m4 (
284 echo ERROR: The C6678 soc does not contain a M4 processor
285 goto CONFIG_ERR
286 )
288 if %PROCESSOR% == arm (
289 echo ERROR: The C6678 soc does not contain an arm processor
290 goto CONFIG_ERR
291 )
292 ) else if %SOC% == C6657 (
293 if %PROCESSOR% == m4 (
294 echo ERROR: The C6657 soc does not contain a M4 processor
295 goto CONFIG_ERR
296 )
298 if %PROCESSOR% == arm (
299 echo ERROR: The C6657 soc does not contain an arm processor
300 goto CONFIG_ERR
301 )
302 ) else (
303 echo ERROR: Invalid soc
304 goto CONFIG_ERR
305 )
307 goto CONFIG_COMPLETE
309 :CONFIG_ERR
310 echo Exiting...
311 echo =========================================================================
312 goto ENDSCRIPT
314 :CONFIG_COMPLETE
315 echo Complete
316 echo =========================================================================
318 REM *****************************************************************************
319 REM * Version Information of the various tools etc required to build the test
320 REM * projects. Customers are free to modify these to meet their requirements.
321 REM *****************************************************************************
323 REM This is to control the CCS version specific project create command
324 REM Set to 'no' when using CCSv5 and CCSv6 or set to 'yes' when using CCSv4
325 set IS_CCS_VERSION_4=no
327 REM Set to 'no' when using QT, EVM, VDB, or other hardware. Set to 'yes' only when using the simulator.
328 set IS_SIMULATOR_SUPPORT_NEEDED=no
330 REM Install Location for CCS
331 set CCS_INSTALL_PATH="C:\ti\ccsv6"
333 REM Workspace where the PDK projects will be created.
334 set MY_WORKSPACE=%PDK_SHORT_NAME%\MyExampleProjects
336 REM macros.ini location
337 set MACROS_FILE=%PDK_SHORT_NAME%\macros.ini
339 REM This is the format of the executable being created
340 REM Valid Values are 'ELF' and 'COFF'
341 set OUTPUT_FORMAT=ELF
343 REM Version of CG-Tools
344 set CGT_VERSION=8.1.0
346 REM Version of CG-ARM-Tools for M4
347 set CGT_M4_VERSION=5.2.5
349 REM Version of XDC
350 set XDC_VERSION=3.32.00.06
352 REM Version of BIOS
353 set BIOS_VERSION=6.45.01.29
355 REM Version of CG-Tools for ARM
356 set CGT_VERSION_ARM=GNU_4.8.4:Linaro
358 REM Version of the IPC
359 set IPC_VERSION=3.42.00.02
361 REM EDMA3 Version
362 set EDMA_VERSION=2.12.01.23
364 REM Version of the PDK
365 set PDK_VERSION=1.0.1
367 REM Version of the NDK
368 set NDK_VERSION=2.24.03.35
370 REM Version of UIA
371 set UIA_VERSION=2.00.03.43
373 REM PDK Part Number & Platform name
374 if %SOC% == K2K (
375 set PDK_PARTNO=TCI6638
376 set PDK_ECLIPSE_ID=com.ti.pdk.k2hk
377 set RTSC_PLATFORM_NAME=ti.platforms.evmTCI6638K2K
378 if %PROCESSOR% == arm (
379 set RTSC_TARGET=gnu.targets.arm.A15F
380 set CCS_DEVICE="Cortex A.TCI6638K2K"
381 )
382 ) else if %SOC% == K2H (
383 set PDK_PARTNO=TCI6636
384 set PDK_ECLIPSE_ID=com.ti.pdk.k2hk
385 set RTSC_PLATFORM_NAME=ti.platforms.evmTCI6636K2H
386 if %PROCESSOR% == arm (
387 set RTSC_TARGET=gnu.targets.arm.A15F
388 set CCS_DEVICE="Cortex A.66AK2H12"
389 )
390 ) else if %SOC% == K2L (
391 set PDK_PARTNO=TCI6630
392 set PDK_ECLIPSE_ID=com.ti.pdk.k2l
393 set RTSC_PLATFORM_NAME=ti.platforms.evmTCI6630K2L
394 if %PROCESSOR% == arm (
395 set RTSC_TARGET=gnu.targets.arm.A15F
396 set CCS_DEVICE="Cortex A.TCI6630K2L"
397 )
398 ) else if %SOC% == K2E (
399 set PDK_PARTNO=66AK2E05
400 set PDK_ECLIPSE_ID=com.ti.pdk.k2e
401 set RTSC_PLATFORM_NAME=ti.platforms.evmC66AK2E
402 if %PROCESSOR% == arm (
403 set RTSC_TARGET=gnu.targets.arm.A15F
404 set CCS_DEVICE="Cortex A.66AK2E05"
405 )
406 ) else if %SOC% == K2G (
407 set PDK_PARTNO=66AK2G02
408 set PDK_ECLIPSE_ID=com.ti.pdk.k2g
409 set RTSC_PLATFORM_NAME=ti.platforms.evmTCI66AK2G02
410 if %PROCESSOR% == arm (
411 set RTSC_TARGET=gnu.targets.arm.A15F
412 set CCS_DEVICE="Cortex A.66AK2G02"
413 )
414 ) else if %SOC% == AM571x (
415 set PDK_PARTNO=AM571X
416 set PDK_ECLIPSE_ID=com.ti.pdk.am57xx
417 set RTSC_PLATFORM_NAME=ti.platforms.evmAM571X
418 if %PROCESSOR% == arm (
419 set RTSC_TARGET=gnu.targets.arm.A15F
420 set CCS_DEVICE="Cortex A.AM5728_RevA"
421 ) else if %PROCESSOR% == m4 (
422 set RTSC_TARGET=ti.targets.arm.elf.M4
423 set CCS_DEVICE="Cortex M.AM5728_RevA"
424 )
425 ) else if %SOC% == AM572x (
426 set PDK_PARTNO=AM572X
427 set PDK_ECLIPSE_ID=com.ti.pdk.am57xx
428 set RTSC_PLATFORM_NAME=ti.platforms.evmAM572X
429 if %PROCESSOR% == arm (
430 set RTSC_TARGET=gnu.targets.arm.A15F
431 set CCS_DEVICE="Cortex A.AM5728_RevA"
432 ) else if %PROCESSOR% == m4 (
433 set RTSC_TARGET=ti.targets.arm.elf.M4
434 set CCS_DEVICE="Cortex M.AM5728_RevA"
435 )
436 ) else if %SOC% == AM335x (
437 set PDK_PARTNO=AM335
438 set PDK_ECLIPSE_ID=com.ti.pdk.am335x
439 set RTSC_PLATFORM_NAME=ti.platforms.evmAM3359
440 set RTSC_TARGET=gnu.targets.arm.A8F
441 set CCS_DEVICE="Cortex A.AM3359.ICE_AM3359"
442 ) else if %SOC% == AM437x (
443 set PDK_PARTNO=AM437
444 set PDK_ECLIPSE_ID=com.ti.pdk.am437x
445 set RTSC_PLATFORM_NAME=ti.platforms.evmAM437X
446 set RTSC_TARGET=gnu.targets.arm.A9F
447 set CCS_DEVICE="Cortex A.AM4379.IDK_AM437X"
448 ) else if %SOC% == C6678 (
449 set PDK_PARTNO=C6678L
450 set PDK_ECLIPSE_ID=com.ti.pdk.c667x
451 set RTSC_PLATFORM_NAME=ti.platforms.evm6678
452 ) else if %SOC% == C6657 (
453 set PDK_PARTNO=C6657
454 set PDK_ECLIPSE_ID=com.ti.pdk.c665x
455 set RTSC_PLATFORM_NAME=ti.platforms.evm6657
456 ) else (
457 REM Need to exit the batch script cleanly
458 set PDK_PARTNO=TCI6634
459 set PDK_ECLIPSE_ID=ti.pdk
460 set RTSC_PLATFORM_NAME=ti.platforms.simKepler
461 )
463 REM RTSC Target
464 REM - Please ensure that you select this taking into account the
465 REM OUTPUT_FORMAT and the RTSC_PLATFORM_NAME
466 if %PROCESSOR% == dsp (
467 if %ENDIAN% == big (
468 set RTSC_TARGET=ti.targets.elf.C66_big_endian
469 set CCS_DEVICE="com.ti.ccstudio.deviceModel.C6000.GenericC64xPlusDevice"
470 ) else (
471 set RTSC_TARGET=ti.targets.elf.C66
472 set CCS_DEVICE="com.ti.ccstudio.deviceModel.C6000.GenericC64xPlusDevice"
473 )
474 )
476 echo PDK_PARTNO : %PDK_PARTNO%
477 echo PDK_ECLIPSE_ID : %PDK_ECLIPSE_ID%
478 echo RTSC_PLATFORM_NAME : %RTSC_PLATFORM_NAME%
479 echo. RTSC_TARGET : %RTSC_TARGET%
480 echo. CCS_DEVICE : %CCS_DEVICE%
481 REM *****************************************************************************
482 REM *****************************************************************************
483 REM Please do NOT change anything below this
484 REM *****************************************************************************
485 REM *****************************************************************************
487 REM Set auto create command by default for use with CCSv5 and CCSv6
488 set AUTO_CREATE_COMMAND=eclipse\eclipsec -noSplash
490 REM If is CCS version 4 then set auto create command for use with CCSv4
491 if .%IS_CCS_VERSION_4% == .yes set AUTO_CREATE_COMMAND=eclipse\jre\bin\java -jar %CCS_INSTALL_PATH%\eclipse\startup.jar
493 REM Set project for Silicon or QT by default
494 set SIMULATOR_SUPPORT_DEFINE=
496 REM If simulator support is needed then set the define
497 if .%IS_SIMULATOR_SUPPORT_NEEDED% == .yes set SIMULATOR_SUPPORT_DEFINE=-ccs.setCompilerOptions "--define SIMULATOR_SUPPORT"
499 REM Goto the PDK Installation Path.
501 pushd %PDK_SHORT_NAME%
503 echo *****************************************************************************
504 echo Detecting all projects in PDK and importing them in the workspace %MY_WORKSPACE%
506 REM Set BOARD to equal the SOC if BOARD is set to "all". All projects for the
507 REM SOC will be picked up
508 if %BOARD% == all set BOARD=%SOC%
509 REM Set MODULE to null string so it picks up all projects of PROCESSOR
510 if %MODULE% == all set MODULE=""
512 if %PROCESSOR% == dsp (
513 REM Search for all the dsp test Project Files in the PDK.
514 for /F %%I IN ('dir /b /s *%MODULE%*%BOARD%*c66*roject.txt') do (
515 set project_detected = 1
517 echo Detected Test Project: %%~nI
519 REM Goto each directory where the test project file is located and create the projects.
520 pushd %%~dI%%~pI
522 REM Execute the command to create the project using the parameters specified above.
523 %CCS_INSTALL_PATH%\%AUTO_CREATE_COMMAND% -data %MY_WORKSPACE% -application com.ti.ccstudio.apps.projectCreate -ccs.name %%~nI -ccs.outputFormat %OUTPUT_FORMAT% -ccs.device %CCS_DEVICE% -ccs.endianness %ENDIAN% -ccs.kind executable -ccs.cgtVersion %CGT_VERSION% -rtsc.xdcVersion %XDC_VERSION% -rtsc.enableDspBios -rtsc.biosVersion %BIOS_VERSION% -rtsc.buildProfile "debug" -rtsc.products "com.ti.sdo.edma3:%EDMA_VERSION%;com.ti.rtsc.IPC:%IPC_VERSION%;com.ti.rtsc.SYSBIOS:%BIOS_VERSION%;%PDK_ECLIPSE_ID%:%PDK_VERSION%;com.ti.rtsc.NDK:%NDK_VERSION%;com.ti.uia:%UIA_VERSION%" -rtsc.platform "%RTSC_PLATFORM_NAME%" -rtsc.target %RTSC_TARGET% -ccs.rts libc.a -ccs.args %%~nI%%~xI %SIMULATOR_SUPPORT_DEFINE% -ccs.overwrite full
525 echo Copying macros.ini
526 copy %MACROS_FILE% %MY_WORKSPACE%\%%~nI\macros.ini
528 popd
529 )
530 )
532 if %PROCESSOR% == arm (
533 REM Search for all the arm test Project Files in the PDK.
534 for /F %%I IN ('dir /b /s *%MODULE%*%BOARD%*arm*roject.txt') do (
535 set project_detected = 1
537 echo Detected Test Project: %%~nI
539 REM Goto each directory where the test project file is located and create the projects.
540 pushd %%~dI%%~pI
542 REM Execute the command to create the project using the parameters specified above.
543 %CCS_INSTALL_PATH%\%AUTO_CREATE_COMMAND% -data %MY_WORKSPACE% -application com.ti.ccstudio.apps.projectCreate -ccs.cmd "" -ccs.name %%~nI -ccs.outputFormat %OUTPUT_FORMAT% -ccs.setLinkerOptions "-L${BIOS_CG_ROOT}/packages/gnu/targets/arm/libs/install-native/arm-none-eabi/lib/fpu" -ccs.device %CCS_DEVICE% -ccs.endianness %ENDIAN% -ccs.kind executable -ccs.cgtVersion "%CGT_VERSION_ARM%" -rtsc.xdcVersion %XDC_VERSION% -rtsc.enableDspBios -rtsc.biosVersion %BIOS_VERSION% -rtsc.buildProfile "debug" -rtsc.products "com.ti.sdo.edma3:%EDMA_VERSION%;com.ti.rtsc.SYSBIOS:%BIOS_VERSION%;%PDK_ECLIPSE_ID%:%PDK_VERSION%;com.ti.rtsc.NDK:%NDK_VERSION%" -rtsc.platform "%RTSC_PLATFORM_NAME%" -rtsc.target %RTSC_TARGET% -ccs.rts libc.a libgcc.a libuart.a libm.a libnosys.a -ccs.args %%~nI%%~xI %SIMULATOR_SUPPORT_DEFINE% -ccs.overwrite full
545 echo Copying macro.ini
546 copy %MACROS_FILE% %MY_WORKSPACE%\%%~nI\macros.ini
548 popd
549 )
550 )
552 if %PROCESSOR% == m4 (
553 REM Search for all the m4 test Project Files in the PDK.
554 for /F %%I IN ('dir /b /s *%MODULE%*%BOARD%*m4*roject.txt') do (
555 set project_detected = 1
557 echo Detected Test Project: %%~nI
559 REM Goto each directory where the test project file is located and create the projects.
560 pushd %%~dI%%~pI
562 REM Execute the command to create the project using the parameters specified above.
563 %CCS_INSTALL_PATH%\%AUTO_CREATE_COMMAND% -data %MY_WORKSPACE% -application com.ti.ccstudio.apps.projectCreate -ccs.cmd "" -ccs.name %%~nI -ccs.outputFormat %OUTPUT_FORMAT% -ccs.device %CCS_DEVICE% -ccs.endianness %ENDIAN% -ccs.kind executable -ccs.cgtVersion "%CGT_M4_VERSION%" -rtsc.xdcVersion %XDC_VERSION% -rtsc.enableDspBios -rtsc.biosVersion %BIOS_VERSION% -rtsc.buildProfile "debug" -rtsc.products "com.ti.sdo.edma3:%EDMA_VERSION%;com.ti.rtsc.SYSBIOS:%BIOS_VERSION%;%PDK_ECLIPSE_ID%:%PDK_VERSION%" -rtsc.platform "%RTSC_PLATFORM_NAME%" -rtsc.target %RTSC_TARGET% -ccs.rts libc.a libgcc.a libuart.a libm.a libnosys.a -ccs.args %%~nI%%~xI %SIMULATOR_SUPPORT_DEFINE% -ccs.overwrite full
565 echo Copying macro.ini
566 copy %MACROS_FILE% %MY_WORKSPACE%\%%~nI\macros.ini
568 popd
569 )
570 )
571 popd
573 if not defined project_detected (
574 echo No projects detected
575 )
577 echo Project generation complete
578 echo *****************************************************************************
580 :ENDSCRIPT