scripts/build_aacip_pkg.bat

   1 @echo off
   2 :: *************************************************************************
   3 ::  FILE           : build_aacip_pkg.bat
   4 ::  DESCRIPTION    :
   5 ::
   6 ::     Builds package for AAC component library.
   7 ::     Assumes setup_env.bat has been called.
   8 ::
   9 :: *************************************************************************
  10
  11 :: %1: package to build (aacdec, aactestapp). i.e. AAC library or AAC test app
  12 :: %2: package destination directory
  13 @echo Executing:  %~fn0 %1 %2
  14
  15 if "%PASDK_ROOT_DIR%" == "" set PASDK_ROOT_DIR=%~dp0..\
  16
  17 :: Set AAC IP local root directory
  18 set AAC_IP_LROOT=%PASDK_ROOT_DIR%3p-ip-fraunhofer\pa\dec\aac
  19
  20 :: Set package directory
  21 if "%2"=="" goto def_prm_pkg_dest_dir
  22
  23 :prm_pkg_dest_dir
  24 set AACIP_PKG_DEST_DIR=%2
  25 goto set_aacip_pkg_name
  26
  27 :def_prm_pkg_dest_dir
  28 set AACIP_PKG_DEST_DIR=%~dp0
  29
  30
  31 :set_aacip_pkg_name
  32 :: Set package name
  33 for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
  34 set DATESTR=%dt:~2,2%%dt:~4,2%%dt:~6,2%
  35
  36 set AACIP_PKG_FNAME=pasdk
  37 if "%PASDK_TARGET_PLATFORM%" NEQ "" set AACIP_PKG_FNAME=%AACIP_PKG_FNAME%_%PASDK_TARGET_PLATFORM%
  38 set AACIP_PKG_FNAME=%AACIP_PKG_FNAME%_%DATESTR%_%2
  39
  40 if /I "%1" == "aacdec" goto build_aacdec_pkg
  41 if /I "%1" == "aactestapp" goto build_aactestapp_pkg
  42 @echo "Invalid package"
  43 goto cleanupenv
  44
  45 :build_aacdec_pkg
  46 :: Build AAC library package
  47 @echo Build package: %1 %AACIP_PKG_DEST_DIR%
  48 set AACDEC_ROOT_DIR=%AAC_IP_LROOT%
  49 if exist Temp\nul ( rmdir /S /Q Temp )
  50 if NOT exist %AACIP_PKG_DEST_DIR%\nul ( mkdir %AACIP_PKG_DEST_DIR% )
  51 @mkdir Temp
  52 @pushd Temp
  53 @mkdir pa\dec\aac\alg
  54 @mkdir pa\dec\aac\alpha
  55 @mkdir pa\build\a15\release
  56 @mkdir pa\docs
  57 @copy /Y %AACDEC_ROOT_DIR%\alg\aac.h pa\dec\aac\alg
  58 @copy /Y %AACDEC_ROOT_DIR%\alg\aac_tii.h pa\dec\aac\alg
  59 @copy /Y %AACDEC_ROOT_DIR%\alg\iaac.h pa\dec\aac\alg
  60 @copy /Y %AACDEC_ROOT_DIR%\alpha\aac_a.h pa\dec\aac\alpha
  61 @copy /Y %AACDEC_ROOT_DIR%\a15\release\aac_elf.lib pa\build\a15\release
  62 @copy /Y %AACDEC_ROOT_DIR%\doc\AACUsersGuide.pdf pa\docs
  63 7z a -tzip -r pkg.zip
  64 @popd
  65 @copy /Y Temp\pkg.zip %AACIP_PKG_DEST_DIR%\%AACIP_PKG_FNAME%.zip
  66 @rmdir /S /Q Temp
  67 set AACDEC_ROOT_DIR=
  68 goto cleanupenv
  69
  70
  71 :build_aactestapp_pkg
  72 :: Build AAC test application package
  73 @echo Build package: %1 %AACIP_PKG_DEST_DIR%
  74 set AACDEC_ROOT_DIR=%AAC_IP_LROOT%
  75 if exist Temp\nul ( rmdir /S /Q Temp )
  76 if NOT exist %AACIP_PKG_DEST_DIR%\nul ( mkdir %AACIP_PKG_DEST_DIR% )
  77 @mkdir Temp
  78 @pushd Temp
  79 @mkdir pa\dec\aac\test\a15
  80 @mkdir pa\dec\aac\test\test_vectors\config
  81 @mkdir pa\dec\aac\test\test_vectors\input
  82 @mkdir pa\dec\aac\test\test_vectors\output
  83 @mkdir pa\docs
  84 @copy /Y %AACDEC_ROOT_DIR%\test\a15\aac_test.out pa\dec\aac\test\a15
  85 @copy /Y %AACDEC_ROOT_DIR%\test\test_vectors\config\A15Testcases.txt pa\dec\aac\test\test_vectors\config
  86 @copy /Y %AACDEC_ROOT_DIR%\doc\AAC_Profiling_Info_A15.xlsx pa\dec\aac\test
  87 @copy /Y %AACDEC_ROOT_DIR%\doc\testappUsersGuide.txt pa\dec\aac\test
  88 7z a -tzip -r pkg.zip
  89 @popd
  90 @copy /Y Temp\pkg.zip %AACIP_PKG_DEST_DIR%\%AACIP_PKG_FNAME%.zip
  91 @rmdir /S /Q Temp
  92 set AACDEC_ROOT_DIR=
  93 goto cleanupenv
  94
  95
  96
  97 :cleanupenv
  98 set AAC_IP_LROOT=
  99 set AACIP_PKG_DEST_DIR=
 100 set DATESTR=
 101 set AACIP_PKG_FNAME=
 102
 103
 104 :end