PASDK-405: added build scripts for NEO6
[processor-sdk/performance-audio-sr.git] / scripts / build_neoip_pkg.bat
1 @echo off
2 :: *************************************************************************
3 ::  FILE           : build_neoip_pkg.bat
4 ::  DESCRIPTION    :
5 ::
6 ::     Builds package for NEO component library.
7 ::     Assumes setup_env.bat has been called.
8 ::
9 :: *************************************************************************
11 :: %1: package to build (neoasp, neotestapp). i.e. NEO library or NEO test app 
12 :: %2: package destination directory
13 @echo Executing:  %~fn0 %1 %2
15 if "%PASDK_ROOT_DIR%" == "" set PASDK_ROOT_DIR=%~dp0..\
17 :: Set NEO IP local root directory
18 set NEO_IP_LROOT=%PASDK_ROOT_DIR%3p-ip-dts\Source_Code\neo
20 :: Set package directory
21 if "%2"=="" goto def_prm_pkg_dest_dir
23 :prm_pkg_dest_dir
24 set NEOIP_PKG_DEST_DIR=%2
25 goto set_neoip_pkg_name
27 :def_prm_pkg_dest_dir
28 set NEOIP_PKG_DEST_DIR=%~dp0
31 :set_neoip_pkg_name
32 :: Set package name
33 for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
34 set DATESTR=%dt:~2,2%%dt:~4,2%%dt:~6,2%
36 set NEOIP_PKG_FNAME=pasdk
37 if "%PASDK_TARGET_PLATFORM%" NEQ "" set NEOIP_PKG_FNAME=%NEOIP_PKG_FNAME%_%PASDK_TARGET_PLATFORM%
38 set NEOIP_PKG_FNAME=%NEOIP_PKG_FNAME%_%DATESTR%_%2
40 if /I "%1" == "neoasp" goto build_neoasp_pkg
41 if /I "%1" == "neotestapp" goto build_neotestapp_pkg
42 @echo "Invalid package"
43 goto cleanupenv
45 :build_neoasp_pkg
46 :: Build NEO library package
47 @echo Build package: %1 %NEOIP_PKG_DEST_DIR%
48 set NEODEC_ROOT_DIR=%NEO_IP_LROOT%
49 if exist Temp\nul ( rmdir /S /Q Temp )
50 if NOT exist %NEOIP_PKG_DEST_DIR%\nul ( mkdir %NEOIP_PKG_DEST_DIR% )
51 @mkdir Temp
52 @pushd Temp
53 @mkdir pa\asp\neo\alg
54 @mkdir pa\asp\neo\alpha
55 @mkdir pa\build\c66x\release
56 @mkdir pa\docs
57 @copy /Y %NEODEC_ROOT_DIR%\alg\neo6.h pa\asp\neo\alg
58 @copy /Y %NEODEC_ROOT_DIR%\alg\neo6_tii.h pa\asp\neo\alg
59 @copy /Y %NEODEC_ROOT_DIR%\alg\ineo6.h pa\asp\neo\alg
60 @copy /Y %NEODEC_ROOT_DIR%\alpha\neo_a.h pa\asp\neo\alpha
61 @copy /Y %NEODEC_ROOT_DIR%\c66x\release\neo.lib pa\build\c66x\release
62 @copy /Y %NEODEC_ROOT_DIR%\doc\NEO_Userguide.pdf pa\docs
63 7z a -tzip -r pkg.zip
64 @popd
65 @copy /Y Temp\pkg.zip %NEOIP_PKG_DEST_DIR%\%NEOIP_PKG_FNAME%.zip
66 @rmdir /S /Q Temp
67 set NEODEC_ROOT_DIR=
68 goto cleanupenv
71 :build_neotestapp_pkg
72 :: Build NEO test application package
73 @echo Build package: %1 %NEOIP_PKG_DEST_DIR%
74 set NEODEC_ROOT_DIR=%NEO_IP_LROOT%
75 if exist Temp\nul ( rmdir /S /Q Temp )
76 if NOT exist %NEOIP_PKG_DEST_DIR%\nul ( mkdir %NEOIP_PKG_DEST_DIR% )
77 @mkdir Temp
78 @pushd Temp
79 @mkdir pa\asp\neo\test\neo_test
80 @mkdir pa\docs
81 @copy /Y %NEODEC_ROOT_DIR%\test\neo_test.out pa\asp\neo\test\neo_test
82 @copy /Y %NEODEC_ROOT_DIR%\test\test_vectors\config\neo_args.txt pa\asp\neo\test\neo_test
83 @copy /Y %NEODEC_ROOT_DIR%\test\test_vectors\reference\neo6.exe pa\asp\neo\test\neo_test
84 @copy /Y %NEODEC_ROOT_DIR%\test\test_vectors\script\neo_ref.bat pa\asp\neo\test\neo_test
85 @copy /Y %NEODEC_ROOT_DIR%\doc\test_ug\neo_test_ug.docx pa\asp\neo\test
86 @copy /Y %NEODEC_ROOT_DIR%\doc\NEO6_Profiling_Info.xlsx pa\asp\neo\test
87 7z a -tzip -r pkg.zip
88 @popd
89 @copy /Y Temp\pkg.zip %NEOIP_PKG_DEST_DIR%\%NEOIP_PKG_FNAME%.zip
90 @rmdir /S /Q Temp
91 set NEODEC_ROOT_DIR=
92 goto cleanupenv
96 :cleanupenv
97 set NEO_IP_LROOT=
98 set NEOIP_PKG_DEST_DIR=
99 set DATESTR=
100 set NEOIP_PKG_FNAME=
103 :end