scripts/build_os_pkg.bat

   1 @echo off
   2 :: *************************************************************************
   3 ::  FILE           : build_os_pkg.bat
   4 ::  DESCRIPTION    :
   5 ::
   6 ::     Builds OS package.
   7 ::     Assumes setup_env.bat has been called.
   8 ::7
   9 :: *************************************************************************
  10
  11 :: %1: package destination directory
  12 @echo Executing:  %~fn0 %1
  13
  14 if "%PASDK_ROOT_DIR%" == "" set PASDK_ROOT_DIR=%~dp0..\
  15
  16 :: Set package name
  17 set OS_PKG_FNAME=processor_audio_sdk_1_00_00_01
  18
  19 if "%1"=="" goto def_prm_pkg_dest_dir
  20
  21 :prm_pkg_dest_dir
  22 set OS_PKG_DEST_DIR=%1
  23 goto build_os_pkg
  24
  25 :def_prm_pkg_dest_dir
  26 set OS_PKG_DEST_DIR=%~dp0
  27
  28 :build_os_pkg
  29 @echo Build OS package %OS_PKG_DEST_DIR%
  30
  31 rem
  32 rem Copy files to package directories
  33 rem
  34
  35 if exist Temp\nul ( rmdir /S /Q Temp )
  36 if NOT exist %OS_PKG_DEST_DIR%\nul ( mkdir %OS_PKG_DEST_DIR% )
  37 @mkdir Temp
  38
  39 @xcopy /E /H /I /Q %PASDK_ROOT_DIR%.git Temp\.git
  40 @xcopy /E /H /I /Q %PASDK_ROOT_DIR%pasdk Temp\pasdk
  41 @xcopy /E /H /I /Q %PASDK_ROOT_DIR%psdk_cust Temp\psdk_cust
  42 @xcopy /E /H /I /Q %PASDK_ROOT_DIR%tools Temp\tools
  43
  44 @xcopy /E /H /I /Q %PASDK_ROOT_DIR%docs Temp\docs
  45 @del /F /Q Temp\docs\PASDK_setup_guide.pdf
  46
  47 @mkdir Temp\scripts
  48 @copy /Y %PASDK_ROOT_DIR%scripts\build_paf_libs.bat Temp\scripts
  49 @copy /Y %PASDK_ROOT_DIR%scripts\build_pdk_libs.bat Temp\scripts
  50 @copy /Y %PASDK_ROOT_DIR%scripts\setup_env.bat Temp\scripts
  51
  52 @pushd Temp
  53
  54 :: Clean PAF build artifacts
  55 @pushd pasdk\paf
  56 @cd
  57 @echo call git clean -fdx
  58 @call git clean -fdx
  59 @popd
  60
  61 :: Clean custom Processor Audio SDK build artifacts
  62 @pushd psdk_cust
  63 @cd
  64 @echo call git checkout -- ./*
  65 @call git checkout -- ./*
  66 @popd
  67
  68 :: Clean PASDK build artifacts
  69 @cd
  70 @echo call git clean -fdx -e Temp
  71 @call git clean -fdx -e Temp
  72
  73 :: Delete FD package from PAF
  74 @pushd pasdk\paf
  75 @if exist pa\asp\del3\nul   ( rmdir /S /Q pa\asp\del3 )
  76 @if exist pa\asp\dem\nul    ( rmdir /S /Q pa\asp\dem )
  77 @if exist pa\asp\dm\nul     ( rmdir /S /Q pa\asp\dm )
  78 @if exist pa\asp\geq3\nul   ( rmdir /S /Q pa\asp\geq3 )
  79
  80 @if exist pa\dec\sng1\nul (
  81     @move /Y pa\dec\sng1\alg\sngerr.h .
  82     @rmdir /S /Q pa\dec\sng1
  83     @mkdir pa\dec\sng1\alg
  84     @move /Y sngerr.h pa\dec\sng1\alg
  85 )
  86
  87 @if exist pa\asp\bm2\nul (
  88     @move /Y pa\asp\bm2\include\bmerr.h .
  89     @rmdir /S /Q pa\asp\bm2
  90     @mkdir pa\asp\bm2\include
  91     @move /Y bmerr.h pa\asp\bm2\include
  92 )
  93
  94 :: Delete other source files from PAF
  95 :: check IP source files (.c, .h) and makefile
  96 @del /F /Q pa\util\da10x_misc\*.*
  97 :: entire DSD directory
  98 @if exist pa\dec\dsd2\nul   ( rmdir /S /Q pa\dec\dsd2 )
  99
 100 @popd
 101
 102 :: Delete git files
 103 @if exist .git\nul ( rmdir /S /Q .git )
 104 @echo del /F /Q /S /AH .git*
 105 @del /F /Q /S /AH .git*
 106 @echo del /F /Q /S .git*
 107 @del /F /Q /S .git*
 108
 109
 110 :: Prepare package
 111 7z a -tzip -r %OS_PKG_FNAME%.zip
 112 @popd
 113 @copy /Y Temp\%OS_PKG_FNAME%.zip %OS_PKG_DEST_DIR%
 114 @rmdir /S /Q Temp
 115
 116
 117 :end
 118
 119 set OS_PKG_FNAME=
 120 set OS_PKG_DEST_DIR=